HBRB: A full featured brb

[maarten]

A full featured brb script, paging, message logging, and idle auto-away. Get hey.wav: http://www.palaceplanet.net/hex/hey.wav. Copy the script from the script section: This is an ON OUTCHAT Script. It has to be placed in your Palace Clients "cyborg.ipt" file in the ON OUTCHAT section. Use Notepad, or plain text editors Like Ultraedit or BBedit for this. Wordprocessors will damage scripts. For more information on editing your Cybrog.ipt, please check the Palace Planet HELP section. After installing type: "hbrb" (don't forget to RELOAD scripts from the file menu of your client)

;HBRB 1.1 by Hex - http://hex.palaceplanet.net/
;This can be a little difficult to set up.
;This script should be edited to fit your style, youll need to
;change New Friend to what people call you, and NF to anything else you might be called.
;Also you can change "brb box" to the name of your favrotie brb prop.
;And "Im Away" to your favorite brb message, maybee "^brb".
;NOTE: Message Logging requires IptVersion 1
;Usage: Just say "hbrb" to go away, youll don your brb prop and say your away message
;If anyone says one of your nick names they will be whispered your brb message, and thier message will be logged.
;When you return say "hbrb" to recieve your messages and turn off the loging/pager/responder script.
;HBrb Signon Segment by Hex
	isLogging GLOBAL { 1 } { 0 } IPTVERSION IFELSE isLogging =
	isPaging GLOBAL 1 isPaging =
	idleTime GLOBAL DATETIME { 2147483647 + } DATETIME 0 < IF idleTime =
;HBrb Inchat Segment by Hex
	isAway GLOBAL isLogging GLOBAL isPaging GLOBAL messageLog GLOBAL bbTxt GLOBAL idleTime GLOBAL
	{	2 isAway = "Im Away (AutoIdle)" bbTxt = 0 ARRAY messageLog = 1 isLogging =
		"; Auto Idle Away - Pager is " { "On" } { "Off" } isPaging IFELSE
		& ", Message Logger is " & { "On" } { "Off" } isLogging IFELSE & LOCALMSG
	} isAway NOT DATETIME { 2147483647 + } DATETIME 0 < IF idleTime - 10 60 * > AND IF
	{	{ bbTxt WHOCHAT PRIVATEMSG } bbTxt "" == NOT IF
		{ {	messageLog oldLog = oldLog LENGTH 1 + ARRAY messageLog =
			{ oldLog t GET messageLog t PUT t ++ } { t oldLog LENGTH < } WHILE
			WHOCHAT WHONAME ": " & CHATSTR & messageLog t PUT
		} isLogging messageLog LENGTH 32 < AND IF } IPTVERSION IF
		{ "hey.wav" SOUND } isPaging IF
	} CHATSTR USERNAME SUBSTR
	  CHATSTR "New Friend" SUBSTR OR
	  CHATSTR "NF" SUBSTR OR
	  WHOCHAT WHOME <> AND isAway AND IF
;HBrb Outchat Segment by Hex
	isAway GLOBAL isLogging GLOBAL isPaging GLOBAL idleTime GLOBAL
	messageLog GLOBAL bbTxt GLOBAL brbProp GLOBAL
	DATETIME { 2147483647 + } DATETIME 0 < IF idleTime =
	{ "; Away Message Logging On" LOCALMSG 1 isLogging = "" CHATSTR = } CHATSTR "log on" == IF
	{ "; Away Message Logging Off" LOCALMSG 0 isLogging = "" CHATSTR = } CHATSTR "log off" == IF
	{ "; Away Paging On" LOCALMSG 1 isPaging = "" CHATSTR = } CHATSTR "pager on" == IF
	{ "; Away Paging Off" LOCALMSG 0 isPaging = "" CHATSTR = } CHATSTR "pager off" == IF
	{	"illbb" brbProp =
		{ brbProp DONPROP } brbProp HASPROP NOT IF
		1 isAway = 0 ARRAY messageLog =
		"$2" GREPSUB bbTxt =
		{ "brb" bbTxt = } bbTxt "" == IF
		"; Away - Pager is " { "On" } { "Off" } isPaging IFELSE
		& ", Message Logger is " & { "On" } { "Off" } isLogging IFELSE & LOCALMSG
		bbTxt SAY "" CHATSTR = 
	} CHATSTR "^hbrb( *)(.*)" GREPSTR IF
	{	"bak" SAY { "" CHATSTR = } isAway 1 == IF 0 isAway =
		{ brbProp REMOVEPROP } { brbProp HASPROP } WHILE
		{ {	0 l = "You recieved " messageLog LENGTH ITOA & " messages. (In Log)" & LOCALMSG
			{ "; " messageLog l GET & LOCALMSG l ++ } { l messageLog LENGTH < } WHILE
		} { "You recieved no messages" LOCALMSG } messageLog LENGTH 1 > IFELSE } IPTVERSION IF
		0 ARRAY messageLog = "" bbTxt =
	} CHATSTR "hbak" == isAway 2 == WHOTARGET NOT AND OR IF