ROOM
	ID 307
	NAME "Scrambler"
	PICT "scrmb.gif"
	PICTURE ID 2 NAME "qu51.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 3 NAME "qu61.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "qu71.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 5 NAME "qu81.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 6 NAME "qu91.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 7 NAME "qu101.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 8 NAME "qu111.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 9 NAME "qu121.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 10 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 11 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "Scrambler"
		DONTMOVEHERE
		OUTLINE 22,324  144,324  144,359  22,359
		LOC 82,342
		SCRIPT
ON SELECT {
{ "Sorry, but the current scrambler is "
ME GETSPOTSTATE WHONAME & LOCALMSG
}
{ WHOME ME SETSPOTSTATE
"@0,0 " USERNAME & " is the scrambler!" & SAY
} ME GETSPOTSTATE WHONAME "." GREPSTR IFELSE
}
ON ENTER { pids GLOBAL
"A935356597B935356670C935356715D935356736E935356774F935356820G935356833H935356858I935356868"
"J935356876K935356905L935356913M935356920N935360840O935360859P935360870Q935360879R935360888" +
"S935360901T935360916U935360922V935360928W935360934X935360943Y935360949Z935360955" +
pids =
"Script and Graphics by Foxy, ©1999" STATUSMSG
}
ON INCHAT { sbler GLOBAL unwrd GLOBAL pids GLOBAL
{ { 1 sbler = } ME GETSPOTSTATE WHOME == IF
} CHATSTR "is the scrambler!$" GREPSTR IF
{ ")applause !" WHOCHAT WHONAME  & " has guessed it!" & ROOMMSG
";The unscrambled word is " unwrd & LOGMSG
0 cc = 4 GETSPOTSTATE 5 + bc = bc 256 bc 20 * - bc =
{ "$2" GREPSUB unwrd = "$1" GREPSUB cl =
pids cl "([-0-9]+)" & GREPSTR POP
"$1" GREPSUB ATOI bc cc 40 * + 107 ADDLOOSEPROP
cc ++
} { unwrd "^(.)(.*)$" GREPSTR } WHILE
8 4 SETSPOTSTATE
{ 2 SELECT } 800 ALARMEXEC
} 2 sbler == CHATSTR unwrd == AND IF
}
ON OUTCHAT { pids GLOBAL sbler GLOBAL unwrd GLOBAL
{ pids "A(.*)B(.*)C(.*)D(.*)E(.*)F(.*)G(.*)H(.*)I(.*)J" GREPSTR POP
"[ $1 $2 $3 $4 $5 $6 $7 $8 $9 ] SETPROPS" GREPSUB STRTOATOM EXEC
pids "J(.*)K(.*)L(.*)M(.*)N(.*)O(.*)P(.*)Q(.*)R(.*)S" GREPSTR POP
"[ $1 $2 $3 $4 $5 $6 $7 $8 $9 ] SETPROPS" GREPSUB STRTOATOM 90 ALARMEXEC
pids "S(.*)T(.*)U(.*)V(.*)W(.*)X(.*)Y(.*)Z(.*)$" GREPSTR POP
"[ $1 $2 $3 $4 $5 $6 $7 $8 ] SETPROPS" GREPSUB STRTOATOM 180 ALARMEXEC
} ISWIZARD CHATSTR "refresh" == AND IF
{ CHATSTR UPPERCASE wrd = wrd scwrd = wrd unwrd =
{ "" scwrd = 0 ln = wrd twrd = "" lnm =
{ lnm "." & lnm = ln ++ } { wrd "." lnm & GREPSTR } WHILE
ln wln =
{ ln RANDOM tln = { "(" tlnm =
{ tlnm "." & tlnm = tln -- } { tln } WHILE
1 tln = tlnm ")(.)(.*)$" + tlnm = }
{ "^(.)(.*)" tlnm = } tln IFELSE
twrd tlnm GREPSTR vld =
{ "$1$3" GREPSUB twrd =
scwrd "$2" GREPSUB & scwrd =
}
{ "$2" GREPSUB twrd =
scwrd "$1" GREPSUB & scwrd =
} tln IFELSE
ln --
} { ln 1 > } WHILE
scwrd twrd + scwrd =
} { scwrd wrd == } WHILE
scwrd wrd = 2 sbler =
0 cc = wln bc = 256 bc 20 * - bc =
wln 5 - 4 SETSPOTSTATE
{ "$2" GREPSUB wrd = "$1" GREPSUB cl =
pids cl "([-0-9]+)" & GREPSTR POP
"$1" GREPSUB ATOI bc cc 40 * + 50 ADDLOOSEPROP
cc ++
} { wrd "^(.)(.*)$" GREPSTR } WHILE
";The scrambled word is " scwrd + SAY
"" CHATSTR =
} sbler 1 == CHATSTR UPPERCASE "^[A-Z]+$" GREPSTR
CHATSTR "....." GREPSTR AND AND
CHATSTR "............." GREPSTR NOT AND IF
{ "" CHATSTR =
} CHATSTR ";reset" ==
CHATSTR " is the scrambler!$" GREPSTR OR IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "Reset"
		DONTMOVEHERE
		OUTLINE 175,324  299,324  300,359  175,359
		LOC 239,341
		SCRIPT
ON SELECT { sbler GLOBAL
{ 0 1 SETSPOTSTATELOCAL 0 1 SETSPOTSTATE
8 4 SETSPOTSTATE
0 sbler = ";reset" SAY "There is no scrambler." ROOMMSG
CLEARLOOSEPROPS
} ISWIZARD 1 GETSPOTSTATE AND
1 GETSPOTSTATE WHOME == OR IF
}
ON INCHAT { sbler GLOBAL
{ 0 sbler = } CHATSTR ";reset" == IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		NAME "Info"
		DONTMOVEHERE
		OUTLINE 333,324  439,324  439,360  333,360
		LOC 386,342
		SCRIPT
ON SELECT { "Instructions are in your log" LOCALMSG
"The person to give a scrambled word clicks on the scrambler button" LOGMSG
"Then after the announcement, they say the word for everyone to guess." LOGMSG
"Words can be from 5 to 12 letters, it is easy to stump people, keep it short and simple." LOGMSG
"Be prepared to give hints if needed." LOGMSG
"Whoever says the correct answer- including the giver of the word- wins." LOGMSG
"Either a wizard or the scrambler may hit reset to open the game up for others." LOGMSG
{ "To keep the props on the server, be in wizard mode and say refresh." LOGMSG
} ISWIZARD IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		OUTLINE 221,111  284,111  283,143  221,144
		LOC 252,127
		PICTS 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 8,0,0 9,0,0 ENDPICTS
		ENDSPOT
	DOOR
		ID 5
		DONTMOVEHERE
		DEST 287
		OUTLINE 7,6  63,6  63,28  7,28
		LOC 33,17
		PICTS 10,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 6
		DONTMOVEHERE
		DEST 347
		OUTLINE 450,4  505,4  505,24  450,24
		LOC 479,14
		PICTS 11,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM