ROOM
	ID 297
	NAME "Spot Pic Bot"
	PICT "blpal49.gif"
	ARTIST "Frodo"
	PICTURE ID 2 NAME "macaw.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 3 NAME "blank.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 5 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		OUTLINE 334,202  369,202  369,250  334,250
		LOC 355,237
		PICTS 3,0,0 2,0,0 ENDPICTS
		SCRIPT
ON ENTER {
{ 1 ME SETSPOTSTATELOCAL } 100 ALARMEXEC
{ "@341 214 Greetings, "  USERNAME  " Welcome to our Palace. If there is anything you need assistance with just say help." + + LOCALMSG } 110 ALARMEXEC
{ 0 ME SETSPOTSTATELOCAL } 800 ALARMEXEC
}
ON OUTCHAT {
mutt GLOBAL
  { "$1" GREPSUB kw =
{ dta =
{ dta 1 GET EXEC
 } kw dta 0 GET == IF
}
[ [ "help"
 {
     1 ME SETSPOTSTATELOCAL
     "@341 214 My commands are: staff, rules, zappo, kissme." LOCALMSG
     { 0 ME SETSPOTSTATELOCAL } 400 ALARMEXEC
} ]
  [ "staff"
  {
      1 ME SETSPOTSTATELOCAL
      "@341 214 The names of the staff members here are in your log." LOCALMSG
      { LOGMSG } [ "The owner of this wonderful palace is" "wizard1" "wizard2" ] FOREACH
      { 0 ME SETSPOTSTATELOCAL } 400 ALARMEXEC
"" CHATSTR =
} ]
  [ "rules"
  {
      1 ME SETSPOTSTATELOCAL
      "@341 214 The Rules here are in your log." LOCALMSG
      { LOGMSG } [ "rule 1" "rule 2" "rule 3" ] FOREACH
      { 0 ME SETSPOTSTATELOCAL } 400 ALARMEXEC
"" CHATSTR =
} ]
  [ "zappo"
     { 1 ME SETSPOTSTATE
     MOUSEPOS my = mx =
      255 0 0 PENCOLOR 3 PENSIZE 341 214
      mx my LINE ")NO" SAY
      { PAINTUNDO } 10 ALARMEXEC
       "@341 214 !Monster Bird Attacks!!" LOCALMSG
      { 0 ME SETSPOTSTATELOCAL } 400 ALARMEXEC
"" CHATSTR =
 } ]
[ "kissme"
{ 1 ME SETSPOTSTATE
 x GLOBAL y GLOBAL WHOCHAT WHOPOS y = x =
 "@341 214 )kiss !MMMMMMM!!!Yummy lil birdy pecks hehehehe!!" LOCALMSG
128 0 128 PENCOLOR 2 PENSIZE PENFRONT
341 214 x y LINE
{ PAINTUNDO } 10 ALARMEXEC
{ x GLOBAL y GLOBAL
x y PENPOS 4 2 LINETO -4 3 LINETO x y PENPOS -4 2 LINETO 4 3 LINETO } 25 ALARMEXEC
{ 0 ME SETSPOTSTATE } 300 ALARMEXEC
"" CHATSTR =
} ]
[ "lol"
{ 1 ME SETSPOTSTATE
"@341 214 LOL...That's too Funny!!" ROOMMSG
{ 0 ME SETSPOTSTATE } 200 ALARMEXEC
} ]
 ] FOREACH
 } CHATSTR "^(.*)$" GREPSTR IF
{ 10 ME SETALARM
1 mutt =
"" CHATSTR = } CHATSTR "mutt on" == ISWIZARD AND IF
{ 0 mutt =
"" CHATSTR = } CHATSTR "mutt off" == ISWIZARD AND IF
}
ON ALARM {
mutt GLOBAL
{ 1 ME SETSPOTSTATE
 [ "@341 214 you call this fun??"
    "@341 214 :I'm Booooored"
    "@341 214 h hush, " WHOCHAT WHONAME + "!" +
    "@341 214 My oh my....isn't " WHOCHAT WHONAME + " just soooooooo sexy??" +
    "@341 214 !BINGO!!"
   ] DUP LENGTH RANDOM GET ROOMMSG
{ 0 ME SETSPOTSTATE } 200 ALARMEXEC
7200 RANDOM 3600 + ME SETALARM
} mutt 1 == IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 174
		OUTLINE 454,4  509,4  509,24  454,24
		LOC 482,13
		PICTS 5,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 2
		DONTMOVEHERE
		DEST 186
		OUTLINE 4,2  56,2  56,28  4,28
		LOC 27,16
		PICTS 4,0,0 ENDPICTS
		ENDDOOR
	ENDROOM