ROOM
	ID 262
	NAME "Prop Generator 3"
	PICT "Oracle.gif"
	ARTIST "script by Foxy"
	PICTURE ID 1 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "Next"
		DONTMOVEHERE
		OUTLINE 255,87  314,87  314,116  255,116
		LOC 279,102
		SCRIPT
;this is the only spot that is required!
;Simply put lines of data in here, according to the comment below
;script by Foxy
ON ALARM
{  [
;add avatar lines here
;format is [ [ -prop ids- ] "description to show in log" ]
[ [ 923841993 923841997 923842001 924322262 923842025 923842038 923842050 923842059 949272941  ] "black vixen" ]
[ [ 906587896 906587902 906588033 906588042 906588053 906588059 906588064 906588071 906588101  ] "elegant vixen" ]
[ [ 908848134 908848139 908848144 908848150 908848155 908848162  ] "vixen combing out hairbrush" ]
[ [ 921644455 921644461 921644466 921644472 921644477 921644482  ] "starry lion" ]
] proparray =
nbrp GLOBAL rfs1 GLOBAL
proparray LENGTH nbrp =
{ proparray rfs1 GET cav =
cav 0 GET SETPROPS cav 1 GET prsc =
"Avatar " rfs1 1 + ITOA + "/" + nbrp ITOA + " " + prsc + " " + LOGMSG
} rfs1 nbrp < rfs1 -1 > AND IF
rfs2 GLOBAL rfs3 GLOBAL rfspd GLOBAL
{ {  "Refreshing " ROOMNAME + " " + rfs2 ITOA + "/" + rfs3 EXEC LENGTH 1 - ITOA +
LOGMSG rfs1 ++ rfspd ME SETALARM
}
{ { rfs1 ++ rfspd ME SETALARM }
{ rfs2 ++ { 0 rfs2 = } rfs2 rfs3 EXEC LENGTH == IF
NAKED rfs3 EXEC rfs2 GET GOTOROOM
}  rfs1 1 + nbrp < IFELSE
} rfs1 -1 == IFELSE
} rfs2 ISWIZARD AND IF
}
ON ENTER { rfs1 GLOBAL prpspt GLOBAL ME prpspt =
-1 rfs1 = 1 ME SETALARM }
ON SELECT{ rfs1 GLOBAL nbrp GLOBAL
rfs1 ++
{ 0 rfs1 = } rfs1 nbrp >= IF
1 ME SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "Previous"
		DONTMOVEHERE
		OUTLINE 166,87  223,87  223,116  165,116
		LOC 164,92
		SCRIPT
;resets the generator to av number one
ON SELECT{ prpspt GLOBAL rfs1 GLOBAL nbrp GLOBAL
rfs1 -- { nbrp 1 - rfs1 = } rfs1 -1 <= IF
1 prpspt SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		NAME "Reset"
		DONTMOVEHERE
		OUTLINE 222,92  254,92  254,115  222,115
		LOC 229,99
		SCRIPT
;moves to previous av in array
ON SELECT{ prpspt GLOBAL rfs1 GLOBAL
0 rfs1 = 1 prpspt SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		NAME "Random"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 218,12  281,12  281,43  218,43
		LOC 248,23
		SCRIPT
;dons a random av from array- and changes your position to it
;for next/previous to use
ON SELECT{ prpspt GLOBAL rfs1 GLOBAL nbrp GLOBAL
nbrp RANDOM rfs1 =
1 prpspt SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 5
		NAME "get prop data"
		OUTLINE 166,53  190,53  190,77  166,77
		LOC 183,64
		SCRIPT
;use this to get a line of data for the generator
;put on the av you want and say "setwear description"
;the description will show up in the log when people use this generator!
ON OUTCHAT {
{ "" CHATSTR =
"[ [ " pp =
{ pp cr USERPROP ITOA & " " & pp = cr ++ }
{ cr NBRUSERPROPS < } WHILE
pp " ] \"$1\" ]" GREPSUB & LOGMSG
} CHATSTR "^setwear (.*)$" GREPSTR IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 6
		DONTMOVEHERE
		DEST 263
		OUTLINE 451,5  507,5  507,31  451,31
		LOC 479,18
		PICTS 1,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDDOOR
	SPOT
		ID 7
		NAME "Jump To Prop"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 212,51  288,51  288,86  212,86
		LOC 250,62
		SCRIPT
;jump to selected av in array
ON SELECT { jump GLOBAL 1 jump = nbrp GLOBAL
"Say a number of av to see from 1 to " nbrp ITOA & LOCALMSG
}
ON OUTCHAT { jump GLOBAL nbrp GLOBAL prpspt GLOBAL rfs1 GLOBAL
{ CHATSTR ATOI jt =
{ jt 1 - rfs1 = 0 jump = "" CHATSTR =
1 prpspt SETALARM
} jt jt nbrp <= AND IF
} CHATSTR ATOI jump AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 8
		NAME "Help"
		DONTMOVEHERE
		OUTLINE 219,118  260,118  260,147  219,147
		LOC 347,214
		SCRIPT
ON SELECT {
"Instructions are in your log." LOCALMSG
"This script has several capabilities.  There is a forward, backward, and reset buttons." LOGMSG
"In addition, there is a Random button that will scroll thru the props randomly when clicked." LOGMSG
"There is a Jump To Prop feature where if you remember you liked prop 4, but are currently at 24, click the Jump To Prop Button." LOGMSG
"It will ask you to put in the number of the prop you wish to 'jump to'." LOGMSG
"There is also a setwear feature.  You can say 'setwear <propname> and get the propids for that prop in your log." LOGMSG
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 9
		DONTMOVEHERE
		DEST 209
		OUTLINE 6,6  64,6  64,28  6,28
		LOC 35,16
		PICTS 2,0,0 ENDPICTS
		ENDDOOR
	ENDROOM