ROOM
	ID 242
	PRIVATE
	NOCYBORGS
	NAME "Yahtzee"
	PICT "yahtzee_back.gif"
	PICTURE ID 1 NAME "onep.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "dice1.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 3 NAME "dice2.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "dice3.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 5 NAME "dice4.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 6 NAME "dice5.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 7 NAME "dice6.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 8 NAME "yahthold.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 9 NAME "yahtck.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 10 NAME "yahtck2.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 11 NAME "yahtck3.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 12 NAME "yahtck4.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 13 NAME "yahtck4p.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 14 NAME "y_redb.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 15 NAME "y_redb2.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 16 NAME "y_redb3.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 17 NAME "unl.gif" ENDPICTURE
	PICTURE ID 18 NAME "lck.gif" ENDPICTURE
	PICTURE ID 19 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 20 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		OUTLINE 34,227  64,227  64,254  34,254
		LOC 49,239
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 2
		OUTLINE 69,227  99,227  99,254  69,254
		LOC 84,239
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 3
		OUTLINE 104,227  134,227  134,254  104,254
		LOC 119,239
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 4
		OUTLINE 141,227  171,227  171,254  141,254
		LOC 156,239
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 5
		OUTLINE 179,227  209,227  209,254  179,254
		LOC 194,239
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 11
		DONTMOVEHERE
		OUTLINE 26,20  213,20  213,35  26,35
		LOC 183,28
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 0 GET crv = ME co =
"@220,28 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 12
		DONTMOVEHERE
		OUTLINE 26,34  213,34  213,49  26,49
		LOC 183,42
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 1 GET 2 * crv = ME co =
"@220,42 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 13
		DONTMOVEHERE
		OUTLINE 26,48  213,48  213,63  26,63
		LOC 183,56
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 2 GET 3 * crv = ME co =
"@220,56 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 14
		DONTMOVEHERE
		OUTLINE 26,63  213,63  213,78  26,78
		LOC 183,71
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 3 GET 4 * crv = ME co =
"@220,71 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 15
		DONTMOVEHERE
		OUTLINE 26,76  213,76  213,91  26,91
		LOC 183,84
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 4 GET 5 * crv = ME co =
"@220,84 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 16
		DONTMOVEHERE
		OUTLINE 26,89  213,89  213,104  26,104
		LOC 183,97
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC 5 GET 6 * crv = ME co =
"@220,97 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 17
		DONTMOVEHERE
		OUTLINE 26,114  213,114  213,129  26,129
		LOC 183,122
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC ddav =  0 crv =
{ tdv = { dt crv = } tdv 2 > IF
} ddav FOREACH
ME co =
"@220,122 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 18
		DONTMOVEHERE
		OUTLINE 26,129  213,129  213,144  26,144
		LOC 183,137
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC ddav =  0 crv =
{ tdv = { dt crv = } tdv 3 > IF
} ddav FOREACH
ME co =
"@220,137 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 19
		DONTMOVEHERE
		OUTLINE 26,143  213,143  213,158  26,158
		LOC 185,151
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd "[145]" GREPSTR NOT 25 * crv =
ME co =
"@220,151 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 20
		DONTMOVEHERE
		OUTLINE 26,157  213,157  213,172  26,172
		LOC 184,165
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd " [12] [12] [12] [12] " GREPSTR 30 *  crv =
ME co =
"@220,165 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 21
		DONTMOVEHERE
		OUTLINE 26,170  213,170  213,185  26,185
		LOC 183,178
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd " 1 1 1 1 1 " GREPSTR 40 *  crv =
ME co =
"@220,178 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 22
		DONTMOVEHERE
		OUTLINE 26,198  213,198  213,213  26,213
		LOC 183,206
		PICTS 1,0,0 9,0,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dt crv = ME co =
"@220,206 That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 23
		DONTMOVEHERE
		OUTLINE 26,184  213,184  213,199  26,199
		LOC 178,191
		PICTS 1,0,0 9,0,0 10,4,0 11,9,0 12,13,0 13,18,0 13,18,0 13,18,0 13,18,0 13,18,0 13,18,0 13,18,0 13,18,0 ENDPICTS
		SCRIPT
ON SELECT { yhtz GLOBAL co GLOBAL dd GLOBAL myturn GLOBAL
crv GLOBAL mysc GLOBAL btt GLOBAL
{ dd "5" SUBSTR yts =
{
{ "@220,188 Sorry, you zeroed out your yahtzee line earlier- you are ineligible for a bonus." LOCALMSG
} yts yhtz 0 < AND IF
{ ")applause " USERNAME " collects a Yahtzee bonus!" & & ROOMMSG
"@511,0 Joker rules-- you get to score it on a regular line as well!" LOCALMSG
100 mysc += ME GETSPOTSTATE 1 + ME SETSPOTSTATE
1 btt = yhtz ++
} yts yhtz 0 > AND btt NOT AND IF
}
{ yts 50 * crv = ME co =
"@220,188 This will score you a " crv ITOA & LOCALMSG
{ "!WARNING: zeroing out this box makes you ineligible for yahtzee bonuses!" LOCALMSG
} crv NOT IF
} yhtz IFELSE
} myturn IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 10
		DONTMOVEHERE
		OUTLINE 171,218  215,217  216,262  171,262
		LOC 194,239
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 9
		DONTMOVEHERE
		OUTLINE 133,218  177,217  178,262  133,262
		LOC 156,239
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 8
		DONTMOVEHERE
		OUTLINE 96,218  140,217  141,262  96,262
		LOC 119,239
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 7
		DONTMOVEHERE
		OUTLINE 61,218  105,217  106,262  61,262
		LOC 84,239
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		DONTMOVEHERE
		OUTLINE 26,218  70,217  71,262  26,262
		LOC 49,239
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 24
		NAME "Start Game"
		DONTMOVEHERE
		OUTLINE 29,331  87,331  87,361  29,361
		LOC 61,345
		SCRIPT
ON ENTER { { "A game of yahtzee is currently being played- click play to join!" LOCALMSG } ME GETSPOTSTATE WHONAME "." GREPSTR IF
{ 0 ME SETSPOTSTATE } ME GETSPOTSTATE WHOME == IF
}
ON SELECT { ref GLOBAL plyrs GLOBAL ad GLOBAL hsc GLOBAL phsc GLOBAL
{ { "A game is currently in session. Click play to join." LOCALMSG }
{ "Resetting game, click again to start a new one." LOCALMSG
0 ME SETSPOTSTATE ";Ÿ5" SAY
{ cr ++ 0 cr SETSPOTSTATE } { cr 23 < } WHILE
} ME GETSPOTSTATE WHONAME "." GREPSTR IFELSE
}
{ WHOME ME SETSPOTSTATE 1 ref = "" plyrs = "-" ad = 0 hsc = "" phsc =
USERNAME " has started a game of Yahtzee! Click play to join!" & ROOMMSG
"@511,0" USERNAME & ", click the roll button to start play after everyone joins." & LOCALMSG
} ME GETSPOTSTATE IFELSE
}
ON INCHAT { ref GLOBAL plyrs GLOBAL phsc GLOBAL hsc GLOBAL
{
{ DUP GLOBAL 0 SWAP =
} [ ref rollt crv mysc ut yhtz plyrs ckbxs myturn co phsc hsc btt ] FOREACH
"" plyrs =
} CHATSTR ";Ÿ5" == IF
{ 0 ref = "" plyrs = "" phsc = 0 hsc =
} ref WHOME ME GETSPOTSTATE <> AND IF
}
ON OUTCHAT { { "" CHATSTR = } CHATSTR "^;Ÿ" GREPSTR IF }
ON ALARM { plyrs GLOBAL hsc GLOBAL phsc GLOBAL ref GLOBAL
{  { "@0,100 !Game over!" ROOMMSG
{ "@100,100 ..and our winner is: " ROOMMSG
"@160,160 )applause !" phsc & "!!" & ROOMMSG
} hsc IF
0 ref = 1 sp =
{ 0 sp SETSPOTSTATE sp ++ } { sp 25 < } WHILE
{ ";Ÿ5" SAY } 60 ALARMEXEC
} plyrs "." GREPSTR NOT IF
} ref IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 25
		NAME "PLAY"
		DONTMOVEHERE
		OUTLINE 28,300  119,300  119,327  28,327
		LOC 77,313
		SCRIPT
;~MediaList~;dice2		
ON ENTER { ad GLOBAL "" ad =
"Script by Foxy, ©2000, Graphics by Aniela, ©2000" STATUSMSG
"For free distribution only!" LOGMSG
}
ON OUTCHAT { ref GLOBAL plyrs GLOBAL
{ "" CHATSTR =
plyrs "^(.*)-[0-9+]-$" GREPSTR POP
"$1" GREPSUB plyrs = 1 25 SETALARM
} ref CHATSTR "remove player" == AND IF
}
ON SELECT { myturn GLOBAL btt GLOBAL
{ co GLOBAL crv GLOBAL mysc GLOBAL ut GLOBAL ckbxs GLOBAL
dd GLOBAL yhtz GLOBAL
{   crv mysc += "I have a score of " mysc ITOA & SAY
0 btt =
{ crv ut += } co 17 < IF
{ 1 co SETSPOTSTATE } co 23 < IF
{ 1 co SETSPOTSTATE dd "5" SUBSTR 2 * 1 - yhtz =
} co 23 == yhtz NOT AND IF
10 cs = 0 ckbxs = 1 vl =
{ cs ++ cs GETSPOTSTATE ckd = { 1 ckd = } cs co == IF
{ vl ckbxs += } ckd IF 2 vl *=
} { cs 22 < } WHILE
0 myturn =
{ ";Ÿ3" SAY }
{  { 35 mysc +=  "@200,200 UPPER TABLE BONUS!" LOCALMSG
} ut 62 > IF
";Ÿ4" WHOME ITOA & "-" & mysc ITOA & SAY
{ DUP GLOBAL 0 SWAP =
} [ rollt crv mysc ut yhtz ckbxs myturn co btt ] FOREACH
} ckbxs 4095 < yhtz NOT OR IFELSE
} co IF
}
{ ";Ÿ1" SAY "dice2" SOUND } myturn IFELSE
}
ON INCHAT { ref GLOBAL plyrs GLOBAL ad GLOBAL
mysc GLOBAL ckbxs GLOBAL ut GLOBAL yhtz GLOBAL
plyrs GLOBAL hsc GLOBAL phsc GLOBAL
ad "." GREPSTR stt =
{ "-" WHOCHAT ITOA & "-" & ad =
{ "You're already in the game, " WHOCHAT WHONAME &
WHOCHAT PRIVATEMSG
}
{ WHOCHAT WHONAME " has joined the game!" & ROOMMSG
";Ÿ2" WHOCHAT ITOA & WHOCHAT PRIVATEMSG
plyrs ad & plyrs =
} plyrs ad SUBSTR IFELSE
{ "" ad = } stt NOT IF
} CHATSTR ";Ÿ1" == ref AND IF
{ ;initialize variables to play
0 mysc = 0 ckbxs = 0 ut = 0 yhtz =
} CHATSTR ";Ÿ2" WHOME ITOA & == IF
{ 90 ME SETALARM
} ";Ÿ3" CHATSTR == ref AND IF
{ "-$1-" GREPSUB pq =
"$2" GREPSUB ATOI ps =
")applause !" "$1" GREPSUB ATOI WHONAME " has finished with a final score of " & &
"$2!" GREPSUB &  ROOMMSG
{ "@150,0 !New high score for the game!" ROOMMSG
"$1" GREPSUB ATOI WHONAME phsc = ps hsc =
} ps hsc > IF
plyrs "^(.*)" pq & "(.*)$" & GREPSTR POP
"$1$2" GREPSUB plyrs =
60 24 SETALARM 120 ME SETALARM
} CHATSTR "^;Ÿ4([0-9]+)-([0-9]+)$" GREPSTR ref AND IF
{ { "$1$2" GREPSUB plyrs =
WHOCHAT WHONAME " has left the game." & ROOMMSG
{ 1 ME SETALARM } "$2" GREPSUB "" == IF
} plyrs "^(.*)-" WHOCHAT ITOA "-(.*)$" & & GREPSTR IF
} CHATSTR ";Ÿ6" == ref AND IF
}
ON ALARM { plyrs GLOBAL
plyrs "^-([0-9]+)-(.*)$" GREPSTR POP
"$1" GREPSUB cp = "$2" GREPSUB oth =
{ oth GREPSUB plyrs = plyrs "^-([0-9]+)-(.*)$" GREPSTR POP
"$1" GREPSUB cp = "$2" GREPSUB oth =
} { cp ATOI WHONAME "." GREPSTR NOT plyrs "" == NOT AND } WHILE
{ "@" cp ATOI WHOPOS ITOA SWAP ITOA " " & SWAP & & cp ATOI WHONAME " is up!" & & ROOMMSG
";Ÿ3" cp & cp ATOI PRIVATEMSG
oth "-" & cp & "-" & plyrs =
}
{ 30 24 SETALARM
} plyrs "" == NOT IFELSE
}
ON LEAVE { ";Ÿ6" SAY }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 26
		NAME "Roll"
		DONTMOVEHERE
		OUTLINE 122,300  213,300  213,328  122,328
		LOC 171,313
		PICTS 1,0,0 14,-50,-34 15,-32,-34 16,-14,-34 ENDPICTS
		SCRIPT
ON ENTER {
{ DUP GLOBAL 0 SWAP =
} [ ref rollt crv mysc ut yhtz plyrs ckbxs myturn co ] FOREACH
}
ON SELECT { ref GLOBAL ad GLOBAL rollt GLOBAL crv GLOBAL myturn GLOBAL
{ "" ad = 1 25 SETALARM }
{ { { ME GETSPOTSTATE 1 + ME SETSPOTSTATE
6 rollt = 0 crv =
1 ME SETALARM
}
{ 1 27 SETALARM
} ME GETSPOTSTATE 3 < IFELSE
} myturn IF
} ref ad ".." GREPSTR AND IFELSE
}
ON INCHAT {
mysc GLOBAL ckbxs GLOBAL ut GLOBAL yhtz GLOBAL
rollt GLOBAL myturn GLOBAL co GLOBAL btt GLOBAL
{ { 0 SWAP SETSPOTSTATE } [ 6 7 8 9 10 ] FOREACH
1 myturn = 11 sp = ckbxs tckbxs =
{ tckbxs DUP 2 / 2 * - sp SETSPOTSTATE
2 tckbxs /= sp ++
} { sp 23 < } WHILE
{ 1 23 SETSPOTSTATE
{ yhtz 23 SETSPOTSTATE } yhtz 1 > IF
}
{ 0 23 SETSPOTSTATE } yhtz IFELSE
0 ME SETSPOTSTATE 0 crv = 0 co =
{ 0 SWAP SETSPOTSTATE } [ 1 2 3 4 5 ] FOREACH
1 btt =
} ";Ÿ3" WHOME ITOA & CHATSTR == IF
}
ON ALARM { rollt GLOBAL dd GLOBAL dt GLOBAL
crv GLOBAL 0 crv = co GLOBAL 0 co =
{ ")dice2" SAY } rollt 6 == IF
{ 0 cr = rollt --
{ cr ++
{ 6 RANDOM 1 + cr SETSPOTSTATE
} cr 5 + GETSPOTSTATE NOT IF
} { cr 5 < } WHILE
30 ME SETALARM
}
{ 80 27 SETALARM
} rollt IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 27
		NAME "Quit"
		DONTMOVEHERE
		OUTLINE 155,333  214,333  214,361  155,361
		LOC 185,347
		SCRIPT
ON SELECT { ref GLOBAL ";Ÿ6" SAY
{ { DUP GLOBAL 0 SWAP =
} [ rollt crv mysc ut yhtz ckbxs myturn co btt ] FOREACH
}
{";Ÿ5" WHOME PRIVATEMSG } ref IFELSE
}
ON ALARM { dt GLOBAL dd GLOBAL btt GLOBAL
0 dt = [ 0 0 0 0 0 0 ] dd =
{ GETSPOTSTATE dv =
dv dt += dd dv 1 - GET 1 + dd dv 1 - PUT
} [ 1 2 3 4 5 ] FOREACH
"[ " { ITOA + " " + } dd FOREACH
" ]" & dd =
{ "@105,268 )applause !YAHTZEE!!" ROOMMSG
0 btt =
} dd "5" SUBSTR IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 28
		NAME "Instructions"
		DONTMOVEHERE
		OUTLINE 92,332  150,332  150,360  92,360
		LOC 121,346
		SCRIPT
ON SELECT {
"Instructions are in your log" STATUSMSG
"To start a Yahtzee game, one person clicks on the start game button and becomes the referee." LOGMSG
"Everyone who wants to play- including the referee- clicks on the Play button to join the game." LOGMSG
"When everyone has joined, the referee clicks the Roll button to start play." LOGMSG
"Anyone can join at any time by clicking play." LOGMSG
"Anyone who wants to quit can click the quit button to do so." LOGMSG
"Anyone who leaves the room automatically quits!" LOGMSG
"Referees- if the player whose turn it is is dead, not there, or for whatever reason, say \x22remove player\x22 to drop them from the game." LOGMSG
"If the referee leaves the room, the game is over!" LOGMSG
"Click on the start game button to reset the game if that happens." LOGMSG
"When play starts, the person whose turn it is clicks roll to roll for the first time and get their dice." LOGMSG
"You lock and unlock the dice by clicking on them, locked dice are marked." LOGMSG
"Click on the score sheet where you want to score, or click roll up to twice more." LOGMSG
"When you click on the score sheet, it tells you what you'll score with that option. If you like it, click Play to score that and finish your turn." LOGMSG
"Due to lag problems, the score may not be reading the dice correctly. If you try to score and see this is happening, just lock all your dice and click roll again to update it." LOGMSG
"When someone fills out their score card, they automatically give their final score." LOGMSG
"Stick around after you're through- the referee remembers the highest score, and will announce it when everyone finishes!" LOGMSG
"Players can click play to rejoin an ongoing game after they finish. In that case the game continues until everyone either quits or finishes their game." LOGMSG
"NOTE: it is highly recommended that the referee have the new palace client!" LOGMSG
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		LOCKABLE
		ID 44
		DONTMOVEHERE
		OUTLINE 487,6  507,6  507,25  487,25
		LOC 497,15
		PICTS 17,0,0 18,0,0 ENDPICTS
		SCRIPT
ON SELECT {
{ ME UNLOCK }
{ ME LOCK } ME ISLOCKED IFELSE
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 29
		DONTMOVEHERE
		DEST 134
		OUTLINE 4,354  62,354  62,380  4,380
		LOC 33,366
		PICTS 19,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 30
		DONTMOVEHERE
		DEST 243
		OUTLINE 448,354  508,354  508,379  448,379
		LOC 480,368
		PICTS 20,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM