ROOM
	ID 224
	NAME "Mouse1 Example"
	PICT "blpal55.gif"
	PICTURE ID 1 NAME "dice1.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "dice2.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 3 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		SHOWFRAME
		OUTLINE 73,31  110,31  110,64  73,64
		LOC 90,44
		PICTS 1,0,0 2,0,0 ENDPICTS
		SCRIPT
ON ENTER { 1 ME SETALARM }
ON ALARM {
{ sp =
MOUSEPOS sp 1 GET > SWAP sp 2 GET > AND
MOUSEPOS sp 3 GET < SWAP sp 4 GET < AND AND insp =
{ insp sp 0 GET SETSPOTSTATELOCAL
} insp sp 0 GET GETSPOTSTATE == NOT IF
} [ ;format is spot id, top left y, top left x, bottom right y, bottom right x
[ 1 31 73 63 110 ]
[ 2 34 140 65 175 ]
] FOREACH
30 ME SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		SHOWFRAME
		OUTLINE 139,33  175,33  175,65  139,65
		LOC 158,48
		PICTS 1,0,0 2,0,0 ENDPICTS
		ENDSPOT
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 225
		OUTLINE 450,356  508,356  508,380  450,380
		LOC 480,368
		PICTS 3,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	SPOT
		ID 5
		NAME "An example of using the mouse to select uneven buttons in an icon bar"
		DONTMOVEHERE
		SHOWNAME
		SHOWFRAME
		OUTLINE 88,112  442,112  442,138  88,138
		LOC 267,119
		SCRIPT
ON SELECT { MOUSEPOS POP y =
{ y < btn += }
[ 111  154  167  195  214  249  262  292  331  370  381  396
419  443 ] FOREACH
[ "An" "example" "of" "using" "the" "mouse" "to" "select"
"uneven" "buttons" "in" "an" "icon" "bar" ] btn GET LOCALMSG
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 6
		DONTMOVEHERE
		DEST 177
		OUTLINE 4,354  62,354  62,379  4,379
		LOC 32,367
		PICTS 4,0,0 ENDPICTS
		SCRIPT
ON ENTER {
"Click on the words or run your mouse over the dice." LOCALMSG }
		ENDSCRIPT
		ENDDOOR
	ENDROOM