ROOM
	ID 221
	NAME "Acro"
	PICT "sage.gif"
	PICTURE ID 2 NAME "acrorule.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 5 NAME "acroplay.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 6 NAME "acrocont.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 7 NAME "acrostrt.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 8 NAME "acrocomp.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 10 NAME "acroplyr.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 11 NAME "acrovote.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "PlaceHolder"
		OUTLINE 484,7  505,7  505,21  484,21
		LOC 256,192
		SCRIPT
ON ENTER { { x = 1 x SETSPOTSTATELOCAL } [ 7 4 5 ] FOREACH
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		NAME "Acro Rules"
		DONTMOVEHERE
		OUTLINE 443,34  480,34  480,51  443,51
		LOC 461,42
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON SELECT { "http://www.tandika.com/palace/acrorules.htm" GOTOURL
"Say \x22reset\x22 to reset the game." LOCALMSG
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		NAME "Playing"
		DONTMOVEHERE
		OUTLINE 444,86  482,86  482,101  444,101
		LOC 462,95
		PICTS 5,0,0 ENDPICTS
		SCRIPT
ON SELECT {
{ { "@" POSX ITOA + "," + POSY ITOA + USERNAME + ", you are player #: " + 8 GETSPOTSTATE 1 + ITOA + LOCALMSG
8 GETSPOTSTATE 1 + ME SETSPOTSTATELOCAL ";#pl" ME GETSPOTSTATE ITOA + SAY } 0 ME GETSPOTSTATE == IF }
{ "There are already 6 players!" LOCALMSG } 6 8 GETSPOTSTATE > IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 5
		NAME "Controller"
		DONTMOVEHERE
		OUTLINE 429,110  498,110  498,130  429,130
		LOC 463,120
		PICTS 6,0,0 ENDPICTS
		SCRIPT
ON SELECT { ctlr GLOBAL ME GETSPOTSTATE x =
{ { ";#ct" SAY 1 ctlr = "!" USERNAME + " is the Controller for this round!" + ROOMMSG }
{ x WHONAME " is already the Controller!" + LOCALMSG } 0 x == IFELSE }
{ "You can't be the Controller, you're not even playing!" LOCALMSG
} 0 4 GETSPOTSTATE < IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		NAME "Rounds"
		DONTMOVEHERE
		OUTLINE 206,60  287,60  287,83  206,83
		LOC 246,72
		PICTS 7,0,0 8,0,0 11,0,0 ENDPICTS
		SCRIPT
;~MediaList~;no		
ON SELECT { ctlr GLOBAL arnd GLOBAL
{ { CLEARLOOSEPROPS
[ "a" "b" "c" "d" "e" "f" "g" "h" "i" "j" "k" "l" "m" "n" "o" "p" "q" "r" "s" "t" "u" "v" "w" "x" "y" "z" ] lts =
0 i = 31 inc = 140 pstx = 6 psty = arnd 3 + c = arnd ++
{ "tombann" lts 26 RANDOM GET + pstx psty ADDLOOSEPROP inc pstx + pstx = i ++ } { c i > } WHILE
";#st" SAY { ")yes !30 seconds to go!" ROOMMSG } 1800 ALARMEXEC
{ ";#tu" SAY ")no !Time's up! Selections to vote on are in your log!" ROOMMSG
";" SAY ";" SAY ";----ACRO VOTING LIST----" SAY
{ ")no !Voting time has ended!" ROOMMSG ";#ve" SAY ";#ts" SAY } 1820 ALARMEXEC
} 3600 ALARMEXEC }
{ "A round is already in progress!" LOCALMSG } 0 ME GETSPOTSTATE == IFELSE }
{ "You can't start the round, you aren't the Controller!" LOCALMSG } 1 ctlr == IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 7
		NAME "Voting"
		DONTMOVEHERE
		OUTLINE 436,144  493,144  493,255  436,255
		LOC 465,200
		PICTS 10,0,0 ENDPICTS
		SCRIPT
ON SELECT { vote GLOBAL
{ MOUSEPOS y = x = { 1 vote = } y 164 <= IF { 2 vote = } y 165 >= y 181 <= AND IF
{ 3 vote = } y 182 >= y 199 <= AND IF { 4 vote = } y 200 >= y 217 <= AND IF
{ 5 vote = } y 218 >= y 235 <= AND IF { 6 vote = } y 236 >= IF
{ ";#pv" 4 GETSPOTSTATE ITOA + " votes for " + vote ITOA + SAY 1 ME SETSPOTSTATELOCAL }
{ 0 vote = "@" POSX ITOA + "," + POSY ITOA + "You can't vote for yourself! Try it again!" + LOCALMSG
} 4 GETSPOTSTATE vote != IFELSE
} ME GETSPOTSTATE 0 == 4 GETSPOTSTATE 0 > AND 4 GETSPOTSTATE 7 < AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 8
		NAME "Inchats"
		OUTLINE 15,352  39,352  39,369  15,369
		LOC 3,375
		SCRIPT
ON INCHAT { meacro GLOBAL score GLOBAL ctlr GLOBAL vote GLOBAL arnd GLOBAL stime GLOBAL
plrstr GLOBAL
{ 0 c = "$1" GREPSUB who = "$2" GREPSUB eltm = "$3" GREPSUB str =
{ "$2" GREPSUB str = c ++ } { str "^(.)(.*)$" GREPSTR } WHILE
c ++ c arnd - 2 - c =
{ "$1" GREPSUB c ITOA + "$2" GREPSUB + plrstr = } plrstr "^(.*p" who + " )[0-9]*(.*)$" + GREPSTR IF
{ "$1" GREPSUB eltm + "$2" GREPSUB + plrstr = } plrstr "^(.*p" who + " [0-9]* )[0-9]*(.*)$" + GREPSTR IF
} CHATSTR "^;#([1-6])=([0-9]*)=ma (.*)$" GREPSTR 1 ctlr == AND IF
{ "$1" GREPSUB who = "$2" GREPSUB vx =
{ "$1" GREPSUB vx + "$2" GREPSUB + plrstr =
} plrstr "^(.*p" who + " [0-9]* [0-9]* )[0-9]*(.*)$" + GREPSTR IF
} CHATSTR "^;#pv([1-6]) votes for ([1-6])$" GREPSTR 1 ctlr == AND IF
{ { { "$1" GREPSUB "$3" GREPSUB + plrstr =
} { plrstr "^(.*)(p[1-6] )(.*)$" GREPSTR } WHILE
plrstr STRTOATOM EXEC plrstr =
[ [ 0 ] [ 0 ] [ 0 ] [ 0 ] [ 0 ] [ 0 ] ] scthem = 0 c =
{ { scthem plrstr c GET 2 GET 1 - GET 0 GET 1 + scthem plrstr c GET 2 GET 1 - GET 0 PUT
} 0 plrstr c GET 2 GET < IF c ++ } { 6 c > } WHILE
0 c = 0 fwho = 9999 ftime =
{ { c 1 + fwho = plrstr c GET 1 GET ftime =
} ftime plrstr c GET 1 GET > IF c ++ } { 6 c > } WHILE
0 c = 0 highscore = 0 whohigh = 0 whospeed =
{ { 0 x = { 1 x = } { { 1 x = } whospeed plrstr c GET 1 GET > IF
} scthem c GET 0 GET highscore > IFELSE
{ c 1 + whohigh = plrstr c GET 1 GET whospeed = scthem c GET 0 GET highscore = } x IF
} scthem c GET 0 GET highscore >= IF c ++ } { 6 c > } WHILE
{ ";" SAY ";" SAY ";" SAY
"!The winner of this round is Player #" whohigh ITOA + " with " + highscore ITOA + " votes!" + ROOMMSG
plrstr whohigh 1 - GET 0 GET bonus = scthem whohigh 1 - GET 0 GET bonus + scthem whohigh 1 - GET 0 PUT
{ "!The winner's Acro Bonus is: " bonus ITOA + " points." + ROOMMSG } 0 bonus < IF
0 c =
{ { ";Player #" c 1 + ITOA + " gets a point for voting for the winner." + SAY
scthem c GET 0 GET 1 + scthem c GET 0 PUT } whohigh plrstr c GET 2 GET == IF c ++
} { 6 c > } WHILE
{ ";Player #" fwho ITOA + " gets a 2-point speed bonus!" + SAY
scthem fwho 1 - GET 0 GET 2 + scthem fwho 1 - GET 0 PUT
} scthem fwho 1 - GET 0 GET 0 > IF }
{ "!Nobody voted, so nobody won! Everyone gets a penalty!" ROOMMSG } 0 highscore < IFELSE
0 c =
{ { ";Player #" c 1 + ITOA + " loses all their points for not voting!" + SAY
0 scthem c GET 0 PUT } plrstr c GET 2 GET 0 == IF c ++ } { 6 c > } WHILE
0 c =
{ ";#pc" c 1 + ITOA + "sx " + scthem c GET 0 GET ITOA + SAY c ++ } { 6 c > } WHILE
";" SAY ";" SAY ";---- Scores for this round ----" SAY 0 c =
{ ";Player #" c 1 + ITOA + ": " + scthem c GET 0 GET ITOA + SAY c ++ } { 6 c > } WHILE
";" SAY ";#fsc" SAY ";" SAY ";" SAY
"!Scores for this round and Players totals are in your log." ROOMMSG
";" SAY ";---- Everyone's New Scores ----" SAY
{ "!End of Game! Winner is the Player with the highest total Score!" ROOMMSG
"Say \x22reset\x22 to play game again." SAY } arnd 5 == IF } CHATSTR ";#ts" == IF
} 1 ctlr == IF
{ 8 GETSPOTSTATE 1 + 8 SETSPOTSTATELOCAL } CHATSTR "^;#pl([1-6])$" GREPSTR IF
{ { score "$2" GREPSUB ATOI + score = } "$1" GREPSUB ATOI 4 GETSPOTSTATE == IF
} CHATSTR "^;#pc([1-6])sx ([0-9]*)$" GREPSTR IF
{ 0 6 SETSPOTSTATELOCAL 1 7 SETSPOTSTATELOCAL
{ ";#pv" 4 GETSPOTSTATE ITOA + " votes for 0" + SAY } 0 vote == IF
} CHATSTR ";#ve" == IF
{ 2 6 SETSPOTSTATELOCAL 0 7 SETSPOTSTATELOCAL ";" meacro + SAY } CHATSTR ";#tu" == IF
{ WHOCHAT 5 SETSPOTSTATELOCAL } CHATSTR ";#ct" == IF
{ ";Player #" 4 GETSPOTSTATE ITOA + "'s score is: " + score ITOA + SAY } CHATSTR ";#fsc" == IF
{ "[ [ p1 0 0 0 ] [ p2 0 0 0 ] [ p3 0 0 0 ] [ p4 0 0 0 ] [ p5 0 0 0 ] [ p6 0 0 0 ] ]" plrstr =
1 6 SETSPOTSTATELOCAL 999 etime = DATETIME stime = 0 vote =
"Player #" 4 GETSPOTSTATE ITOA + ": none" + meacro = } CHATSTR ";#st" == IF
{ "Player #" ME GETSPOTSTATE ITOA + ": none" + meacro = 0 score = 0 ctlr = 0 arnd =
0 4 SETSPOTSTATELOCAL 0 5 SETSPOTSTATELOCAL 0 6 SETSPOTSTATELOCAL 1 7 SETSPOTSTATELOCAL
0 8 SETSPOTSTATELOCAL "" CHATSTR =
} CHATSTR ";#reset" == IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 9
		NAME "Outchats"
		OUTLINE 15,319  38,319  38,339  15,339
		LOC 69,366
		SCRIPT
ON OUTCHAT { meacro GLOBAL stime GLOBAL
{ ";#reset" SAY } CHATSTR "reset" == IF
{ { DATETIME etime = etime stime - etime =
";#" 4 GETSPOTSTATE ITOA + "=" + etime ITOA + "=ma " + "$1" GREPSUB + SAY
"Player #" 4 GETSPOTSTATE ITOA + ": " + "$1" GREPSUB + meacro = }
{ "You can only give your acro during the Competition Round!" LOCALMSG
} 6 GETSPOTSTATE 1 == IFELSE "" CHATSTR =
} CHATSTR "^acro=(.*)$" GREPSTR IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 10
		NAME "Back"
		DONTMOVEHERE
		SHOWNAME
		DEST 91
		OUTLINE 446,322  487,322  487,344  446,344
		LOC 467,325
		ENDDOOR
	DOOR
		ID 11
		NAME "Forward"
		DONTMOVEHERE
		SHOWNAME
		DEST 107
		OUTLINE 440,348  494,348  494,372  440,372
		LOC 467,354
		ENDDOOR
	ENDROOM