ROOM
	ID 12416
	NOPAINTING
	NOCYBORGS
	NAME "SoundRoom Mp3"
	PICT "download.gif"
	ARTIST "XT"
	PICTURE ID 101 NAME "XTSoundForest3.gif" ENDPICTURE
	PICTURE ID 102 NAME "XTPanelNone.gif" ENDPICTURE
	PICTURE ID 103 NAME "XTPanelSel1.gif" ENDPICTURE
	PICTURE ID 104 NAME "XTPanelSel2.gif" ENDPICTURE
	PICTURE ID 105 NAME "XTPanelPrev.gif" ENDPICTURE
	PICTURE ID 106 NAME "XTPanelNext.gif" ENDPICTURE
	PICTURE ID 107 NAME "XTPanelPlay.gif" ENDPICTURE
	PICTURE ID 108 NAME "XTPanelStop.gif" ENDPICTURE
	PICTURE ID 109 NAME "XTPanelHelp.gif" ENDPICTURE
	PICTURE ID 1 NAME "XTBackwardNormal.gif" ENDPICTURE
	PICTURE ID 2 NAME "XTForwardNormal.gif" ENDPICTURE
	PICTURE ID 3 NAME "XTPlayNormal.gif" ENDPICTURE
	PICTURE ID 4 NAME "XTHelpNormal.gif" ENDPICTURE
	PICTURE ID 5 NAME "XTBackwardPush.gif" ENDPICTURE
	PICTURE ID 6 NAME "XTForwardPush.gif" ENDPICTURE
	PICTURE ID 7 NAME "XTPlayPush.gif" ENDPICTURE
	PICTURE ID 8 NAME "XTHelpPush.gif" ENDPICTURE
	PICTURE ID 9 NAME "XTStopNormal.gif" ENDPICTURE
	PICTURE ID 10 NAME "XTStopPush.gif" ENDPICTURE
	PICTURE ID 11 NAME "XTSelection1Push.gif" ENDPICTURE
	PICTURE ID 12 NAME "XTSelection1Normal.gif" ENDPICTURE
	PICTURE ID 13 NAME "XTSelection2Push.gif" ENDPICTURE
	PICTURE ID 14 NAME "XTSelection2Normal.gif" ENDPICTURE
	PICTURE ID 15 NAME "XTPlayLock.gif" ENDPICTURE
	PICTURE ID 16 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 17 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 8832
		NAME "SoundRoom1"
		OUTLINE 242,179  270,179  270,206  242,206
		LOC 256,192
		PICTS 101,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 2010
		DONTMOVEHERE
		OUTLINE 9,271  136,271  136,324  9,324
		LOC 73,301
		PICTS 102,0,0 103,0,0 104,0,0 105,0,0 106,0,0 107,0,0 108,0,0 109,0,0 ENDPICTS
		SCRIPT
ON ENTER { 30 ME SETALARM 0 ME SETSPOTSTATELOCAL }
ON ALARM { lastState GLOBAL ME GETSPOTSTATE lastState =
     lTemp GLOBAL 0 lTemp =
     MOUSEPOS tempY = tempX =
  {{1 lTemp =} tempX 12 > tempX 69   < AND IF
   {2 lTemp =} tempX 75 > tempX 132  < AND IF
  } tempY 329 > tempY 349 < AND IF
  {{3 lTemp =} tempX 11 > tempX 32   < AND IF
   {4 lTemp =} tempX 38 > tempX 56   < AND IF
   {5 lTemp =} tempX 63 > tempX 83   < AND IF
   {6 lTemp =} tempX 90 > tempX 109  < AND IF
   {7 lTemp =} tempX 114 > tempX 134 < AND IF
  } tempY 355 > tempY 372 < AND IF
  {lTemp ME SETSPOTSTATELOCAL} lastState lTemp <> IF
     30 ME SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 1010
		DONTMOVEHERE
		OUTLINE 9,353  136,353  136,375  9,375
		LOC 72,363
		ENDSPOT
	DOOR
		ID 3456
		NAME "Help"
		DONTMOVEHERE
		DEST 1024
		OUTLINE 114,355  134,355  134,372  115,372
		LOC 124,363
		PICTS 4,0,0 8,0,0 ENDPICTS
		SCRIPT
ON ENTER { SSound GLOBAL 0 ME SETSPOTSTATELOCAL
"@400,25 ^The instructions are in your log." SAY {0 0 MOVE} 600 ALARMEXEC
10 ME SETALARM
{{GLOBAL} [cSound x1] FOREACH
 thearray LENGTH noarray =
 noarray 2 - nomusic =
; Force x1 always into the array range and make the list wrap around
{0 x1 =} {{noarray 1 - x1 =} x1 0 < IF} x1 noarray >= IFELSE
 thearray x1 GET cSound =
 "" cSoundName = ".mp3" ext =
 {cSound LENGTH cl =
  cSound 0 GET Sname =
  {cSound 1 GET Bytes =} {"0" Bytes =} cl 0 > IFELSE
  {cSound 2 GET Singer =} {"Unknown" Singer =} cl 1 > IFELSE
  Sname ext & cSound =
  cSound Bytes & "Kb" & Singer & "@" & "@"  STRINDEX cSoundL =
; Now format with the maximum STATUSMSG length = 64 Bytes
  7 cSoundL + 1 + 1 + SBS = 64 SBS - NSpace =
  " ______________________________" 0 NSpace SUBSTRING " " & Space =
  cSound Space & Bytes & "Kb" & " " & Singer & cSoundName =
  0 5678 SETSPOTSTATELOCAL
 } {2 5678 SETSPOTSTATELOCAL} x1 0 > x1 noarray 1 - < AND IFELSE
  {0 x1 = cSoundName " (Start Of " ME SPOTNAME & " List)" & cSoundName =} x1 1 < IF
  {noarray 1 - x1 = cSoundName " (End Of " ME SPOTNAME & " List)" & cSoundName =} x1 noarray 1 - >= IF
  x1 ITOA mn = {"0" mn & mn =} mn "@" & "@"  STRINDEX 1 == IF
  mn "-" & nomusic ITOA & ") " & cSoundName & LOGMSG
} SSound DEF
}
ON SELECT { "click" SOUND 1 ME SETSPOTSTATELOCAL
100 ME SETALARM
}
ON ALARM {
"Instructions to use the Sound Buttons:" LOGMSG
"Click on one of the Selections buttons to select a Music List" LOGMSG
"Click on the Forward Button to show the next Music in the List" LOGMSG
"Click on the Play Button to Download/Play the current Music" LOGMSG
"Click on the Play Button again after you receive the file to hear it" LOGMSG
" " LOGMSG
"The Sound Buttons, from left to right, do the following:" LOGMSG
" 1. Music Selection 1                              2. Music Selection 2" LOGMSG
" 3. Backward Music List                          4. Forward Music List" LOGMSG
" 5. Download/Play Current Music             6. Stop Music" LOGMSG
" 7. Help (display this information)" LOGMSG
"All song files have the information about the size!" STATUSMSG
"Have fun and enjoy!" STATUSMSG
0 ME SETSPOTSTATELOCAL
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 1111
		NAME "Selection 1"
		DONTMOVEHERE
		OUTLINE 13,330  70,330  70,349  13,349
		LOC 41,339
		PICTS 11,0,0 12,0,0 ENDPICTS
		SCRIPT
; Door 1 list
ON ENTER { 0 ME SETSPOTSTATELOCAL 1 2348 SETSPOTSTATELOCAL
x1 GLOBAL 0 x1 = cSound GLOBAL "" cSound = ; Reset values from previous sound rooms
}
ON SELECT { x1 GLOBAL 0 x1 = cSound GLOBAL "" cSound = "Click" SOUND
0 ME SETSPOTSTATELOCAL 1 2348 SETSPOTSTATELOCAL 2 5678 SETSPOTSTATELOCAL
"-------> " ME SPOTNAME & ". Now go to Forward button" & STATUSMSG
}
ON ALARM {
{
;Put the sound file names in thearray.
[ ""
["AllForLove" "802" "R.Stewart\/B.Adams\/Sting"]
["Angels" "673" "Robbie Williams"]
["Cherish" "681" "Kool And The Gang"]
["Daniel" "707" "Wilson Phillips"]
["Drive" "678" "The Cars"]
["DreamOn" "606" "Nazareth"]
["EverythingIDoIDoItForYou" "941" "Bryan Adams"]
["FatherAndSon" "486" "Cat Stevens"]
["FireAndRain" "590" "James Taylor"]
["ForTheLoveOfAPrincess" "721" "From BraveHeart"]
["HaveYouEverReallyLovedAWoman" "835" "Bryan Adams"]
["HereComesTheSun" "536" "Beatles"]
["Hero" "757" "Mariah Carey"]
["HowCanYouMendABrokenHeart" "595" "Bee Gees"]
["HowDeepIsYourLove" "790" "Bee Gees"]
["HuntingHighAndLow" "650" "A-Ha"]
["ImNotInLove" "1035" "10 Cc"]
["If" "447" "Bread"]
["IStartTheJoke" "491" "Bee Gees"]
["ItMightBeYou" "728" "Stephen Bishop"]
["TheRoadAhead" "705" "City To City"]
""
] thearray =
SSound GLOBAL SSound EXEC
 } ME GETSPOTSTATE NOT IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 2348
		NAME "Selection 2"
		DONTMOVEHERE
		OUTLINE 77,329  134,329  134,349  77,349
		LOC 105,339
		PICTS 13,0,0 14,0,0 ENDPICTS
		SCRIPT
; Door 2 list
ON SELECT { x1 GLOBAL 0 x1 = cSound GLOBAL "" cSound = "Click" SOUND
0 ME SETSPOTSTATELOCAL 1 1111 SETSPOTSTATELOCAL 2 5678 SETSPOTSTATELOCAL
"-------> " ME SPOTNAME & ". Now go to Forward button" & STATUSMSG
}
ON ALARM {
{
[ ""
["IWillComeToYou" "707" "Hanson"]
["IWillMakeLoveToYou" "769" "Boys II Man"]
["LaSolitudine" "690" "Laura Pausini"]
["LoveHurts" "759" "Nazareth"]
["LoveIsAllAround" "680" "Wet Wet Wet"]
["ManIFeelLikeAWomen" "681" "Shania Twain"]
["QuitPlayingGamesWithMyHeart" "670" "Backstreet Boys"]
["Sacrifice" "904" "Sinead O\'Connor"]
["SlaveToLove" "780" "Bryan Ferry"]
["SmokeGetsInYourEyes" "467" "Platters"]
["StuckOnYou" "551" "Lionel Richie"]
["Sunshine" "662" "Nazareth"]
["TakeMyBreathAway" "750" "G.Moroder\/T.Whitlock"]
["TheCloserIGetToYou" "818" "Roberta Flack"]
["TrulyMadlyDeeply" "812" "Savage Garden"]
["TwilightTime" "408" "The Platters"]
["UnchainedMelody" "641" "Righteus Brothers"]
["Weird" "707" "Hanson"]
["WomanInChains" "914" "Tears For Fears"]
["YouAreStillTheOne" "618" "Shania Twain"]
""
] thearray =
SSound GLOBAL SSound EXEC
 } ME GETSPOTSTATE NOT IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 5678
		NAME "Download/Play Sound"
		DONTMOVEHERE
		OUTLINE 63,355  83,355  83,372  63,372
		LOC 73,363
		PICTS 3,0,0 7,0,0 15,0,0 ENDPICTS
		SCRIPT
; Download/Play Button
ON ENTER {2 ME SETSPOTSTATELOCAL}
ON SELECT { cSound GLOBAL xSound GLOBAL cSound xSound = "click" SOUND
{"None music from the 'Selection 1/2' was selected" LOCALMSG EXIT} xSound "" == IF
MIDISTOP {xSound GLOBAL xSound SOUND} 50 ALARMEXEC
1 ME SETSPOTSTATELOCAL {xSound GLOBAL ")" xSound & SAY} 300 ALARMEXEC
"Downloading/Playing " xSound & STATUSMSG
{0 ME SETSPOTSTATELOCAL} 800 ALARMEXEC
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 6234
		NAME "Backward"
		DONTMOVEHERE
		OUTLINE 11,355  32,355  32,372  11,372
		LOC 21,363
		PICTS 1,0,0 5,0,0 ENDPICTS
		SCRIPT
; Backward Button
ON ENTER {0 ME SETSPOTSTATELOCAL}
ON SELECT {1 ME SETSPOTSTATELOCAL "click" SOUND
x1 GLOBAL
1 x1 -=
1 1111 SETALARM
2 2348 SETALARM
{0 ME SETSPOTSTATELOCAL} 100 ALARMEXEC
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 7890
		NAME "Forward"
		DONTMOVEHERE
		INVISIBLE
		OUTLINE 38,355  56,355  56,372  38,372
		LOC 47,363
		PICTS 2,0,0 6,0,0 ENDPICTS
		SCRIPT
; Forward Button
ON ENTER {0 ME SETSPOTSTATELOCAL}
ON SELECT {1 ME SETSPOTSTATELOCAL "click" SOUND
x1 GLOBAL
1 x1 +=
1 1111 SETALARM
2 2348 SETALARM
{0 ME SETSPOTSTATELOCAL} 100 ALARMEXEC
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		LOCKABLE
		ID 86
		NAME "Stop Sounds"
		DONTMOVEHERE
		OUTLINE 90,355  109,355  109,372  90,372
		LOC 99,363
		PICTS 9,0,0 10,0,0 ENDPICTS
		SCRIPT
; Stop Button
ON ENTER {0 ME SETSPOTSTATELOCAL}
ON SELECT {1 ME SETSPOTSTATELOCAL "click" SOUND
MIDISTOP 86 UNLOCK ; Trick to stop Mp3 files
0 5678 SETSPOTSTATELOCAL
{0 ME SETSPOTSTATELOCAL} 100 ALARMEXEC
}
ON OUTCHAT {{MIDISTOP 86 UNLOCK "" CHATSTR =} CHATSTR "ms" == IF}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 21
		DONTMOVEHERE
		DEST 1588
		OUTLINE 7,6  63,6  63,28  7,28
		LOC 33,17
		PICTS 16,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 22
		DONTMOVEHERE
		DEST 148
		OUTLINE 450,4  505,4  505,24  450,24
		LOC 479,14
		PICTS 17,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM