ROOM
	ID 111
	NOPAINTING
	NAME "Prop Repository"
	PICT "blpal51.gif"
	PICTURE ID 2 NAME "hnext.gif" TRANSCOLOR 57 ENDPICTURE
	PICTURE ID 3 NAME "hprev.gif" ENDPICTURE
	PICTURE ID 5 NAME "arrowll.gif" TRANSCOLOR 56 ENDPICTURE
	PICTURE ID 6 NAME "arrowrr.gif" TRANSCOLOR 56 ENDPICTURE
	SPOT
		ID 1
		NAME "Reset"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 242,97  297,97  297,126  242,126
		LOC 270,106
		SCRIPT
ON ENTER {
CurRec GLOBAL 0 CurRec =
bname GLOBAL "Props1" bname =
AlarmId GLOBAL 3 AlarmId =
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
ON SELECT {
CurRec GLOBAL 0 CurRec =
"Resetting buttons to start" LOGMSG naked
}
ON OUTCHAT {
CurRec GLOBAL
AlarmId GLOBAL
{ "" CHATSTR =  CurRec --  1 AlarmId SETALARM } "-" CHATSTR == IF
{ "" CHATSTR =  CurRec ++  1 AlarmId SETALARM } "+" CHATSTR == IF
{ "" CHATSTR = "$1" GREPSUB ATOI CurRec =  1 AlarmId SETALARM } CHATSTR
"^=(.*)$" GREPSTR IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "Previous"
		DONTMOVEHERE
		OUTLINE 132,101  191,101  191,125  132,125  123,113
		LOC 153,113
		PICTS 3,0,0 ENDPICTS
		SCRIPT
ON SELECT {
CurRec GLOBAL CurRec --
AlarmId GLOBAL 1 AlarmId SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		NAME "Next"
		DONTMOVEHERE
		OUTLINE 343,99  402,99  412,111  402,123  343,123
		LOC 380,111
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON ALARM { [
"958703651 958703668 958703674"
"958958815"
"958958805"
"958958773"
"958958837"
"957247021"
"958703651 958703668 958703674"
"958958815"
"958958805"
"958958773"
] TheArray =
TheArray LENGTH NoArray =
bname GLOBAL
CurRec GLOBAL
{ 1 CurRec  =  } CurRec NoArray >  IF
{ NoArray CurRec =  } CurRec 1 <  IF
bname  ": row " + CurRec itoa + "/" + NoArray itoa + logmsg
"["  TheArray CurRec 1 - get + "] SETPROPS" + STRTOATOM EXEC
}
ON SELECT {
CurRec GLOBAL CurRec ++
AlarmId GLOBAL 1 AlarmId SETALARM
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 7
		DONTMOVEHERE
		DEST 218
		OUTLINE 4,358  57,358  57,379  4,379
		LOC 29,369
		PICTS 5,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 8
		DONTMOVEHERE
		DEST 193
		OUTLINE 452,355  509,355  509,380  452,380
		LOC 481,367
		PICTS 6,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
		ENDSCRIPT
		ENDDOOR
	ENDROOM