ROOM
	ID 1094
	HIDDEN
	NAME "Lines n' Boxes prep"
	PICT "dots3.gif"
	SPOT
		ID 1
		OUTLINE 448,354  508,354  508,379  448,379
		LOC 62,50
		SCRIPT
ON ENTER { lndhrt GLOBAL hrtst GlOBAL 1 hrtst =
{ hn =
{
{ "" CHATSTR = } CHATSTR "^;ƒ" GREPSTR IF
{ [ 941583667 941583591 941584115 ] SETPROPS
} CHATSTR "refresh" == ISWIZARD AND IF
{ PAINTCLEAR CLEARLOOSEPROPS
{ ys GLOBAL ys STRTOATOM EXEC yss =
255 191 0 PENCOLOR 3 PENSIZE
0 ca =
{ lnd =  0 cl = ca ++
{ lnd 2 / tv =
{ { 941584115 160 cl 25 * + 65 ca 25 * + ADDLOOSEPROP  }
{ 160 cl 25 * + 65 ca 25 * + PENPOS 25 0 LINETO
} ca 3 < IFELSE
} lnd tv 2 * - IF
tv lnd = cl ++
} { cl 8 < } WHILE
} yss FOREACH
{ 0 ca = xs GLOBAL xs STRTOATOM EXEC xss =
{ lnd =  0 cl = ca ++
{ lnd 2 / tv =
{ 135 ca 25 * + 90 cl 25 * + PENPOS 0 25 LINETO
} lnd tv 2 * - IF
tv lnd = cl ++
} { cl 8 < } WHILE
} xss FOREACH
} 60 AlARMEXEC
} 60  ALARMEXEC rdrw GLOBAL 1 rdrw =
} CHATSTR "redraw" == 1 GETSPOTSTATE WHOME == AND IF
} hn 1 == IF
{ rdrw GLOBAL
{ gp GLOBAL pp GLOBAL gg pp + tp = 0 dl =
{ dl ++ "$1" GREPSUB tp =
} { tp "^..(.*)" GREPSTR } WHILE
135 dl 4 * + ME SETALARM
} CHATSTR "redraw" == rdrw WHOCHAT WHOME == AND AND IF
{ ys STRTOATOM EXEC yss = xs STRTOATOM EXEC xss =
[ 1 2 4 8 16 32 64 128 ] pwr =
255 191 0 PENCOLOR 3 PENSIZE
{ "$1" GREPSUB dr =  "$2" GREPSUB ATOI wo = 0 act =
"$3" GREPSUB ATOI wi = { 7 wi = } 8 wi == IF
{ yss wo GET bl =
{ bl pwr wi GET +  yss wo PUT 1 act =
{ 941584115 160 wi 25 * + 90 wo 25 * + ADDLOOSEPROP }
{ 160 wi 25 * + 90 wo 25 * + PENPOS 25 0 LINETO
} wo 2 < IFELSE
{ yss wo 1 - GET upr =
{ xss wi GET lfs = xss wi 1 + GET rgs =
{ wi pc = wo 1 - pr = putpiece EXEC
} lfs pwr wo 1 - GET / DUP 2 / 2 * -
rgs pwr wo 1 - GET / DUP 2 / 2 * - AND IF
} upr pwr wi GET / DUP 2 / 2 * - IF
} wo IF
{ yss wo 1 + GET lwr =
{ xss wi GET lfs = xss wi 1 + GET rgs =
{ wi pc = wo  pr = putpiece EXEC
} lfs pwr wo GET / DUP 2 / 2 * -
rgs pwr wo GET / DUP 2 / 2 * - AND IF
} lwr pwr wi GET / DUP 2 / 2 * - IF
} wo 8 < IF
} bl pwr wi GET / DUP 2 / 2 * - NOT IF
}
{ xss wo GET bl =
{ bl pwr wi GET + xss wo PUT 1 act =
160 wo 25 * + 90 wi 25 * + PENPOS 0 25 LINETO
{ xss wo 1 - GET lfs =
{ yss wi GET upr = yss wi 1 + GET lwr =
{ wo 1 - pc = wi pr = putpiece EXEC
} upr pwr wo 1 - GET/ DUP 2 / 2 * -
lwr pwr wo 1 - GET / DUP 2 / 2 * - AND IF
} lfs pwr wi GET / DUP 2 / 2 * - IF
} wo IF
{ xss wo 1 + GET rgs =
{ yss wi GET upr = yss wi 1 + GET lwr =
{ wo pc = wi pr = putpiece EXEC
} upr pwr wo GET / DUP 2 / 2 * -
lwr pwr wo GET / DUP 2 / 2 * - AND IF
} rgs pwr wi GET / DUP 2 / 2 * - IF
} wo 8 < IF
} bl pwr wi GET / DUP 2 / 2 * - NOT IF
} dr "r" == IFELSE
"[ " xs = "[ " ys = 0 st  =
{ xs xss st GET ITOA " " + + xs =
ys yss st GET ITOA " " + + ys =
st ++
} { st 9 < } WHILE
xs "]" + xs = ys "]" + ys =
{ 3 lbt - lbt = } 1 act == IF lbt 1 - 4 SETSPOTSTATE { ")fh_write" SAY } act IF
} CHATSTR ";ƒ([rc])([0-8])([0-8])$" GREPSTR WHOCHAT lbt GETSPOTSTATE == AND IF
{ 0 2 SETSPOTSTATE 0 1 SETSPOTSTATE 2 4 SETSPOTSTATE 0 1 SETSPOTSTATELOCAL
"." ln = 0 gr = 0 pr = 0 lbt =
{ { gr ++ } gp ln GREPSTR IF
{ pr ++ } pp ln GREPSTR IF
".." ln + ln =
} { pp ln GREPSTR gp ln GREPSTR OR } WHILE
"@256,80 Final score is" ROOMMSG
"@256,130 Green: " gr ITOA + ROOMMSG
"@256,180 Purple: " pr ITOA + ROOMMSG
"\"@256,250 )applause !"
{ "We have a TIE!\"" }
{ { USERNAME }
{ 2 GETSPOTSTATE WHONAME }
gr pr > IFELSE
" is our WINNER!\"" +
} gr pr == IFELSE
+ " ROOMMSG" + STRTOATOM 120 ALARMEXEC
} "[ 255 255 255 255 255 255 255 255 255 ]"  xs == ys xs == AND IF
} WHOME 1 GETSPOTSTATE == IF
} hn 2 == IF
{ pp GLOBAL gp GLOBAL tpp GLOBAL tgp GLOBAL rdrw GLOBAL 0 rdrw =
{ "0" tpp = } pp "." GREPSTR NOT IF
{ "0" tgp = } gp "." GREPSTR NOT IF
{ pp tpp = } tpp "." GREPSTR NOT IF
{ gp tgp = } tgp "." GREPSTR NOT IF
{ "$3" GREPSUB tpp = "$1" GREPSUB ATOI pc =
"$2" GREPSUB ATOI pr = { "0" tpp = } tpp "." GREPSTR NOT IF
941583591 160 pc 25 * + 93 pr 25 * + ADDLOOSEPROP
} tpp "^(.)(.)(.*)" GREPSTR IF
{ "$3" GREPSUB tgp = "$1" GREPSUB ATOI pc =
"$2" GREPSUB ATOI pr = { "0" tgp = } tgp "." GREPSTR NOT IF
941583667 160 pc 25 * + 93 pr 25 * + ADDLOOSEPROP
} tgp "^(.)(.)(.*)" GREPSTR IF
{ 30 ME SETALARM }
{ "" tpp = "" tgp =
} tpp "0" == NOT tgp "0" == NOT OR IFElSE
} hn 3 == IF
} lndhrt DEF
1093 GOTOROOM
}
; "fh_write.wav-*"
		ENDSCRIPT
		ENDSPOT
	ENDROOM