ROOM	
	ID 1004
	NOCYBORGS
	NAME "Paintball Arena 4"
	PICT "pbroom.gif"
	DOOR
		ID 1
		DEST 1001
		OUTLINE 473,155  509,147  509,309  473,295
		LOC 506,137
		SCRIPT
ON ENTER {
{ GLOBAL } [ team fon base ] FOREACH
{ 1000 GOTOROOM } team NOT IF
[ [ 923100285 ] [ -1284536128  ] ] team 1 - GET SETPROPS
}
ON INCHAT {
{ GLOBAL } [ team bls mxi sts base ] FOREACH
[ "!SPLAT!" "!SPLOT!" ] team 1 - GET fs =
{ "$1" GREPSUB ATOI POSX - DUP * dx =
"$2" GREPSUB ATOI POSY - DUP * dy =
{ { ";you hit me." WHOCHAT PRIVATEMSG mxi -- }
{ ";you got me!" WHOCHAT PRIVATEMSG
"!" WHOCHAT WHONAME + " GOT ME!" + SAY
NAKED 0 team = base GOTOROOM
} mxi IFELSE } dx 485 < dy 485 < AND IF
} CHATSTR "@([0-9]+),([0-9]+) .pop " fs + GREPSTR IF
{ 50 bls += "You have " bls ITOA +  " points." + STATUSMSG
} CHATSTR ";you got me!" == WHOCHAT WHOME != AND IF
{ 10 bls += "You have " bls ITOA +  " points." + STATUSMSG
} CHATSTR ";you hit me." == WHOCHAT WHOME != AND IF
{ { ch =
{ "$1" GREPSUB ATOI ch 1 GET STRTOATOM EXEC +=
} CHATSTR ch 0 GET GREPSTR IF
} [ [ "^give ([0-9]+) ammo" "sts" ]
[ "^give ([0-9]+) shields" "mxi" ]
[ "^give ([0-9]+) points" "bls" ] ] FOREACH
} WHOCHAT WHOME != IF
}
ON OUTCHAT {
{ GLOBAL } [ bls ngt tst sts fon team ken mxi ocs fst ] FOREACH
ocs EXEC fst EXEC
{ fw = { "" CHATSTR = } CHATSTR fw GREPSTR IF }
[ "@[0-9]+,[0-9]+ !SPL.T!" ";you got me!" ";you hit me."
] FOREACH
{ fst GLOBAL } fon IF
{ { fw = { "" CHATSTR = "Whisper!" STATUSMSG } CHATSTR fw GREPSTR IF }
[ "^give [0-9]+ ammo" "^give [0-9]+ shields" "^give [0-9]+ points"
] FOREACH
} WHOTARGET NOT IF
{ ch = "$1" GREPSUB ATOI ga =
{ "$1" GREPSUB ATOI ga =
{ "You can't give what you don't have!" STATUSMSG "" CHATSTR = }
{ ga ch 1 GET STRTOATOM EXEC -=
} ga ch 1 GET STRTOATOM EXEC > IFELSE
} CHATSTR ch 0 GET GREPSTR IF
} [ [ "^give ([0-9]+) ammo" "sts" ] [ "^give ([0-9]+) shields" "mxi" ]
[ "^give ([0-9]+) points" "bls" ] ] FOREACH
}
ON ALARM { fon GLOBAL 1 fon = }
ON LEAVE { { CLEARLOOSEPROPS } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM