ROOM
	ID 704
	DROPZONE
	NAME "Instant Palace Menu"
	PICT "blpal39.gif"
	PICTURE ID 404 NAME "ipmenu2b.gif" ENDPICTURE
	PICTURE ID 405 NAME "ipmenuop2e.gif" ENDPICTURE
	PICTURE ID 406 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 407 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 321
		DONTMOVEHERE
		OUTLINE 0,360  43,360  43,383  0,383
		LOC 201,372
		PICTS 404,-179,0 405,6,0 ENDPICTS
		SCRIPT
;at gates and server entry rooms
ON ENTER {
Instpal GLOBAL
MOUSEPOS + 0 == Instpal =
0 ME SETSPOTSTATELOCAL
ipmenu1 GLOBAL {
ME GETSPOTSTATE NOT ME SETSPOTSTATELOCAL
} ipmenu1 DEF
ipmenu2 GLOBAL {
{ 0 321 SETSPOTSTATELOCAL } 321 GETSPOTSTATE 1 == IF
} ipmenu2 DEF
ipmenu3 GLOBAL {
Instpal GLOBAL
{
{
"pop" SOUND
maxavatar GLOBAL
curavatar GLOBAL
curavatar --
{ maxavatar 1 - curavatar = } -1 curavatar == IF
convert GLOBAL convert EXEC
}
{ direction GLOBAL 2 direction = 10 325 SETALARM
} Instpal IFELSE
} 321 GETSPOTSTATE 1 == IF
} ipmenu3 DEF
ipmenu4 GLOBAL {
{ "@55,292 Click the \"Next\" and \"Back\" buttons to cycle through avatars." LOCALMSG
} 321 GETSPOTSTATE 1 == IF
} ipmenu4 DEF
ipmenu5 GLOBAL {
Instpal GLOBAL
MOUSEPOS + 0 == Instpal =
0 ME SETSPOTSTATELOCAL
index GLOBAL -1 index =
;IP section
maxavatar GLOBAL
curavatar GLOBAL
convert GLOBAL
18 maxavatar =
{ 0 faceoffset =
  2 coloroffset =
coloroffset 13 * faceoffset + curavatar + avataroffset =
avataroffset 13 / color =
avataroffset 13 color * - face  =
2 color * color =
color SETCOLOR face SETFACE
} convert DEF
} ipmenu5 DEF
ipmenu6 GLOBAL {
Instpal GLOBAL
{
{
"pop" SOUND
maxavatar GLOBAL
curavatar GLOBAL
curavatar ++
{ 0 curavatar = } maxavatar curavatar == IF
convert GLOBAL convert EXEC
}
{
direction GLOBAL 1 direction = 10 325 SETALARM
} Instpal IFELSE
} 321 GETSPOTSTATE 1 == IF
} ipmenu6 DEF
ipmenu7 GLOBAL {
index GLOBAL direction GLOBAL
[
[ 953938129 953938144 953938181 953938170 953941197 ]
[ 953939042 953939008 953938990 953939019 953939299 953939028 ]
[ 953934683 953934739 953934824 953934788 953934804 ]
[ 953939329 953939343 953939370 953939381 953939357 953939408 ]
[ 953941163 953941174 953941181 953941190 953941197 ]
] avatar =
avatar LENGTH numavs =
{ { index ++ } { 0 index = } index 1 + numavs < IFELSE } direction 1 == IF
{ { numavs 1 - index = } { index -- } index 1 < IFELSE } direction 2 == IF
avatar index GET SETPROPS
index 1 + ITOA avnum =
"Av " avnum + "/" + numavs ITOA + LOGMSG
} ipmenu7 DEF
ipmenu8 GLOBAL {
{ 82 GOTOROOM } 321 GETSPOTSTATE 1 == IF
} ipmenu8 DEF
ipmenu9 GLOBAL {
{ "http://www.palacetools.com/palace/" url =
   "Now opening your browser to " url & LOCALMSG
   "\"" url & "\" NETGOTO" & STRTOATOM 60 ALARMEXEC
} 321 GETSPOTSTATE 1 == IF
} ipmenu9 DEF
ipmenu10 GLOBAL {
{ "http://www.palacetools.com/palace/site.php?id=2033" url =
   "Now opening your browser to " url & LOCALMSG
   "\"" url & "\" NETGOTO" & STRTOATOM 60 ALARMEXEC
} 321 GETSPOTSTATE 1 == IF
} ipmenu10 DEF
}
ON SELECT { ipmenu1 GLOBAL ipmenu1 EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 322
		DONTMOVEHERE
		OUTLINE 42,360  55,360  55,383  42,383
		LOC 170,286
		SCRIPT
ON SELECT { ipmenu2 GLOBAL ipmenu2 EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 323
		DONTMOVEHERE
		OUTLINE 55,360  112,360  112,383  55,383
		LOC 184,286
		SCRIPT
ON SELECT { ipmenu3 GLOBAL ipmenu3 EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 324
		DONTMOVEHERE
		OUTLINE 112,360  161,360  161,383  112,383
		LOC 240,286
		SCRIPT
ON SELECT { ipmenu4 GLOBAL ipmenu4 EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 325
		DONTMOVEHERE
		OUTLINE 161,360  214,360  214,383  161,383
		LOC 290,286
		SCRIPT
ON ENTER { ipmenu5 GLOBAL ipmenu5 EXEC }
ON SELECT { ipmenu6 GLOBAL ipmenu6 EXEC }
ON ALARM { ipmenu7 GLOBAL ipmenu7 EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 326
		DONTMOVEHERE
		OUTLINE 214,360  272,360  272,383  214,383
		LOC 343,286
		SCRIPT
ON SELECT { ipmenu8 GLOBAL ipmenu8 EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 327
		DONTMOVEHERE
		OUTLINE 272,360  340,360  340,383  272,383
		LOC 403,286
		SCRIPT
ON SELECT { ipmenu9 GLOBAL ipmenu9 EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 328
		DONTMOVEHERE
		OUTLINE 340,360  412,360  412,383  340,383
		LOC 293,286
		SCRIPT
ON SELECT { ipmenu10 GLOBAL ipmenu10 EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 351
		OUTLINE 3,302  15,302  15,315  3,315
		LOC 202,338
		PICTS 405,0,100 ENDPICTS
		ENDSPOT
	DOOR
		ID 10
		DONTMOVEHERE
		DEST 256
		OUTLINE 7,6  63,6  63,28  7,28
		LOC 33,17
		PICTS 406,0,0 ENDPICTS
		SCRIPT
ON ENTER {
"This script will go at your gate.  Follow the arrow to get the script for any other rooms you may want this in." LOCALMSG }
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 11
		DONTMOVEHERE
		DEST 705
		OUTLINE 450,4  505,4  505,24  450,24
		LOC 479,14
		PICTS 407,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM