ROOM
	ID 236
	NOPAINTING
	NOCYBORGS
	NAME "Irritation"
	PICT "irritation.gif"
	ARTIST "Cid"
	PICTURE ID 1 NAME "Dice1.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "Dice2.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 3 NAME "Dice3.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "Dice4.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 5 NAME "Dice5.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 6 NAME "Dice6.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 7 NAME "cidpl1.gif" ENDPICTURE
	PICTURE ID 8 NAME "blank.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 9 NAME "cidpl2.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 10 NAME "cidpl3.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 11 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 12 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "Roll Dice"
		DONTMOVEHERE
		OUTLINE 219,5  292,5  292,38  219,38
		LOC 273,21
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 ENDPICTS
		SCRIPT
; dice rolling script in spot 1
; put in pics of die faces 1 - 6....
ON SELECT {
turn GLOBAL
roll GLOBAL
numroll GLOBAL
numroll ++
{
{
0 i =
{ 6 RANDOM ME SETSPOTSTATE i ++ } { i  20 < } WHILE }
{ ME GETSPOTSTATE 6 - ME SETSPOTSTATE }
ME GETSPOTSTATE 6 < IFELSE
6 RANDOM 1 + roll =
roll 1 - ME SETSPOTSTATE
{ 1 3 SETSPOTSTATE  }  { turn 1 + 3 SETSPOTSTATE  } turn 2 GETSPOTSTATE == IFELSE
40 2 SETALARM
}
{ "It's not your turn!" STATUSMSG }
3 GETSPOTSTATE turn == IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "Game Spot"
		DONTMOVEHERE
		DEST 168
		OUTLINE 27,11  95,11  95,42  27,42
		LOC 61,26
		SCRIPT
;~MediaList~;silence.wav,boing.wav,slide.wav,bonk.wav		
; "action" script in spot 2
ON ENTER {
"silence.wav" SOUND
"boing.wav" SOUND
"slide.wav" SOUND
"bonk.wav" SOUND
ME GETSPOTSTATE numplay =
{ 100 8 SETSPOTSTATE } 8 GETSPOTSTATE 0 == IF
place GLOBAL
roll GLOBAL
add GLOBAL
numroll GLOBAL
turn GLOBAL
0 turn =
0 numroll =
0 add =
0 roll =
0 place =
}
ON ALARM {
roll GLOBAL
place GLOBAL
pcoords GLOBAL
gcoords GLOBAL
{ place roll + place = } place roll + 50 <= IF
[ " 452 321 "  " 385 321 "  " 321 319 "  " 255 320 "  " 191 319 "  " 127 320 "  " 63 320 "
" 63 278 "  " 128 277 "  " 192 277 "  " 254 276 "  " 320 276 "  " 386 278 "  " 451 278 "
" 450 236 "  " 385 238 "  " 321 240 "  " 254 237 "  " 193 236 "  " 126 237 "  " 62 235 "
" 62 198 "  " 126 197 "  " 192 197 "  " 254 197 "  " 320 196 "  " 387 198 "  " 451 198 "
" 451 152 "  " 385 151 "  " 321 152 "  " 254 152 "  " 191 152 "  " 126 152 "  " 62 151 "
" 62 111 "  " 127 113 "  " 192 111 "  " 253 111 "  " 320 110 "  " 384 111 "  " 445 110 "
" 450 68 "  " 383 69 "  " 322 70 "  " 255 70 "  " 192 69 "  " 128 71 "  " 63 70 "  " 60 26 "  ] gcoords =
gcoords  place 1 - GET pcoords =
pcoords " SETPOS" + STRTOATOM  EXEC
40 3 SETALARM
}
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		DONTMOVEHERE
		OUTLINE 431,6  491,6  491,36  431,36
		LOC 461,21
		SCRIPT
ON SELECT {
"Rules are in your log..." LOCALMSG
"**************************************************" LOGMSG
"**                    Irritation                          **" LOGMSG
"**      A race game for up to 3 players       **" LOGMSG
"**                     By Cid                            **" LOGMSG
"**************************************************" LOGMSG
"1. Reset the game by clicking the \"Reset Game\" button." LOGMSG
"2. After Resetting, select player numbers in order." LOGMSG
"3. Player 1 rolls first and play continues in order." LOGMSG
"4. Each player rolls the die in turn and their av is automatically moved." LOGMSG
"5. Landing on a Green arrow takes you up." LOGMSG
"6. Landing on a Red arrow takes to down." LOGMSG
"7. The winner is whoever reaches the Goal first." LOGMSG
"8. You have to land on the Goal by an exact count." LOGMSG
"9. When the game is over, the Reset Button must be pressed to start another." LOGMSG
"*************************************************" LOGMSG
"Today's low score:  " 8 GETSPOTSTATE ITOA & LOGMSG
}
ON ALARM {
place GLOBAL
gcoords GLOBAL
add GLOBAL
numroll GLOBAL
[  0 0 9 0 0 0 0
0 -3 0 7 0 -11 0
0 -3 0 7 0 -11 0
0 -3 0 0 5 -11 0
0 -3 9 0 0 -11 0
0 -3 0 0 0 3 0
0 0 -5 0 0 -11 0 0 0 ] moves =
[ " 452 321 "  " 385 321 "  " 321 319 "  " 255 320 "  " 191 319 "  " 127 320 "  " 63 320 "
" 63 278 "  " 128 277 "  " 192 277 "  " 254 276 "  " 320 276 "  " 386 278 "  " 451 278 "
" 450 236 "  " 385 238 "  " 321 240 "  " 254 237 "  " 193 236 "  " 126 237 "  " 62 235 "
" 62 198 "  " 126 197 "  " 192 197 "  " 254 197 "  " 320 196 "  " 387 198 "  " 451 198 "
" 451 152 "  " 385 151 "  " 321 152 "  " 254 152 "  " 191 152 "  " 126 152 "  " 62 151 "
" 62 111 "  " 127 113 "  " 192 111 "  " 253 111 "  " 320 110 "  " 384 111 "  " 445 110 "
" 450 68 "  " 383 69 "  " 322 70 "  " 255 70 "  " 192 69 "  " 128 71 "  " 63 70 "  " 60 26 "  ] gcoords =
moves place 1 - GET add =
{ ")slide" SAY 2 SETFACE } add 0 < IF
{ ")boing" SAY 8 SETFACE} add 0 > IF
{ ")bonk" SAY 5 SETFACE } add 0 == place 50 < AND IF
gcoords  place 1 -  GET pcoords =
pcoords " SETPOS" & STRTOATOM  EXEC
{ "!)applause I win!!!" SAY
"Todays low score:  " 8 GETSPOTSTATE ITOA & SAY
"I finished in only " numroll ITOA & " moves." & SAY
{ numroll 8 SETSPOTSTATE
"!New low score!  " numroll ITOA & SAY } numroll 8 GETSPOTSTATE < IF
} place 50 == IF
{  40 4 SETALARM
40 5 SETALARM
40 6 SETALARM  }
{  place add + place =
40 ME SETALARM  } add 0 == IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		OUTLINE 48,354  157,354  143,381  16,381
		LOC 91,367
		PICTS 8,0,0 7,0,0 ENDPICTS
		SCRIPT
; Player 1 select/indicate in spot 4
ON SELECT {
{ ")bonk" SAY
1 ME SETSPOTSTATE
NAKED
0 SETCOLOR
5 SETFACE
place GLOBAL
0 place  =
turn GLOBAL
1 turn =
numroll GLOBAL
0 numroll =
{ 2 getspotstate 1 + 2 setspotstate } 2 GETSPOTSTATE 3 < IF
USERNAME " is Player 1..." + SAY }
{ "Sorry, Player 1 is taken... select again"  LOCALMSG }
ME GETSPOTSTATE 0 == IFELSE
}
ON ALARM {
{ 1 ME SETSPOTSTATE } {0 ME SETSPOTSTATE } 3 GETSPOTSTATE 1 ==  IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 5
		OUTLINE 206,355  318,355  329,380  197,380
		LOC 262,367
		PICTS 8,0,0 9,0,0 ENDPICTS
		SCRIPT
; Player 2 select/indicate in spot 5
ON SELECT {
{ ")bonk" SAY
1 ME SETSPOTSTATE
NAKED
10 SETCOLOR
5 SETFACE
place GLOBAL
0 place  =
turn GLOBAL
2 turn =
numroll GLOBAL
0 numroll =
{ 2 getspotstate 1 + 2 setspotstate } 2 GETSPOTSTATE 3 < IF
USERNAME " is Player 2..." + SAY }
{ "Sorry, Player 2 is taken... select again"  LOCALMSG }
ME GETSPOTSTATE 0 == IFELSE
}
ON ALARM {
{ 1 ME SETSPOTSTATE } {0 ME SETSPOTSTATE } 3 GETSPOTSTATE 2 ==  IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		OUTLINE 361,355  473,355  502,380  376,380
		LOC 428,367
		PICTS 8,0,0 10,0,0 ENDPICTS
		SCRIPT
; Player 3 select/indicate in spot 6
ON SELECT {
{ ")bonk" SAY
1 ME SETSPOTSTATE
NAKED
3 SETCOLOR
5 SETFACE
place GLOBAL
0 place  =
turn GLOBAL
3 turn =
numroll GLOBAL
0 numroll =
{ 2 getspotstate 1 + 2 setspotstate } 2 GETSPOTSTATE 3 < IF
USERNAME " is Player 3..." + SAY }
{ "Sorry, Player 3 is taken... select again"  LOCALMSG }
ME GETSPOTSTATE 0 == IFELSE
}
ON ALARM {
{ 1 ME SETSPOTSTATE } {0 ME SETSPOTSTATE } 3 GETSPOTSTATE 3 ==  IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 7
		NAME "reset"
		DONTMOVEHERE
		OUTLINE 356,4  421,4  421,37  356,37
		LOC 389,15
		SCRIPT
; game reset in spot 7
ON SELECT {
{ "Are you sure you want to RESET this game?" ROOMMSG
" Select \"Reset\" again to confirm... " ROOMMSG
1 ME SETSPOTSTATELOCAL }
{ 0 ME SETSPOTSTATELOCAL
"One moment... " USERNAME & " is resetting game..." & ROOMMSG
1 i =
{ 0 i SETSPOTSTATE i ++ } { i 8 < } WHILE
1 3 SETSPOTSTATE
" Game is reset... Select your player number to begin new game..." ROOMMSG
} ME GETSPOTSTATE 0 == IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 8
		OUTLINE 24,45  488,45  488,349  24,350
		LOC 256,192
		SCRIPT
; spotstate indicates Low score in spot 8
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 9
		DONTMOVEHERE
		DEST 206
		OUTLINE 4,354  62,354  62,380  4,380
		LOC 33,366
		PICTS 11,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 10
		DONTMOVEHERE
		DEST 191
		OUTLINE 448,354  508,354  508,379  448,379
		LOC 480,368
		PICTS 12,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM