ROOM
	ID 217
	NAME "Hammer's Dressup"
	PICT "blpal48.gif"
	ARTIST "Script By Hammer"
	PICTURE ID 1 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		OUTLINE 13,357  34,357  34,380  13,380
		LOC 23,368
		SCRIPT
ON OUTCHAT{
;;Dressup v.1 By Hammer© 6/6/2k
;;The dress portion of the script is on an alarm so it cant be bypassed
;;uses no outchat globals only 2 inchat and alarm
;;Also would recommend changing all globals to something of your choice
;;for security reasons.
{
0 i =
{";dd "
{
i USERPROP ITOA & " " &
i ++
} { i NBRUSERPROPS < } WHILE
"" & WHOTARGET PRIVATEMSG}
{"You have to whisper it"STATUSMSG}WHOTARGET IFELSE
"" CHATSTR =
}CHATSTR "dressup" == IF
;;**The section below stops people from faking the script but it adds what they say to their log.
;;**This was done to stop people from trying to bypass this section of the script.
{
"$1" GREPSUB said=
{USERNAME":        ;dd "& said &LOGMSG}
{"*" USERNAME"*:        ;dd "& said &&LOGMSG}WHOTARGET NOT IFELSE
""CHATSTR=
}CHATSTR"^;dd (-*[-0-9 ]*)$"GREPSTR IF
;;This section is the accept part of the script assuring the dress is mutual.
;;Sets an alarm to do the dressing.This way there is no way to dress someone without them wanting it.
{
1 ME SETALARM
""CHATSTR=
}CHATSTR"dressme"==IF
}
ON INCHAT{
mrp GLOBAL
sss GLOBAL
{
1 sss=
"$1" GREPSUB mrp=
WHOCHAT WHONAME " wants to give you their avatar. To accept it say \"dressme\""&LOCALMSG
}CHATSTR"^;dd (-*[-0-9 ]*)$"GREPSTR WHOCHAT WHOME == NOT AND  IF
}
ON ALARM{
mrp GLOBAL
sss GLOBAL
{""ROOMMSG "[ " mrp & " ] SETPROPS" & STRTOATOM EXEC 0 ss= }1 sss==IF
}
ON ENTER {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 93
		OUTLINE 6,7  62,7  62,26  6,26
		LOC 33,16
		PICTS 1,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 4
		DONTMOVEHERE
		DEST 216
		OUTLINE 446,7  506,7  506,29  446,29
		LOC 477,17
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
		ENDSCRIPT
		ENDDOOR
	ENDROOM