ROOM	
	ID 12324
	PRIVATE
	NOPAINTING
	HIDDEN
	NAME "Casino Hall"
	PICT "download.gif"
	ARTIST "XT"
	PICTURE ID 1 NAME "CasinoHall.gif" ENDPICTURE
	SPOT
		ID 1000
		OUTLINE 243,186  287,186  287,224  243,224
		LOC 256,192
		PICTS 1,0,0 ENDPICTS
		ENDSPOT
	DOOR
		ID 200
		DEST 12323
		OUTLINE 141,134  196,134  196,238  141,238
		LOC 166,182
		SCRIPT
ON ENTER {
{"You are using an old client! The Casino games will not work fine for you" ROOMMSG} IPTVERSION 1 < IF
; Put This code in the Entrance (first Casino room)
{GLOBAL} [RoulettePrevRoom RouletteRoom BJackPrevRoom] FOREACH
{GLOBAL} [BlackJackRoom CrapsPrevRoom CrapsRoom SiteAddress] FOREACH
SiteAddress GLOBAL "xt.yi.org" SiteAddress = ; Here goes your palace site address
12323 BJackPrevRoom =
12319 BlackJackRoom =
12328 CrapsPrevRoom =
12318 CrapsRoom =
12327 RoulettePrevRoom =
12317 RouletteRoom =
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 30
		DEST 12325
		OUTLINE 259,130  322,130  322,257  259,243
		LOC 275,198
		SCRIPT
ON ENTER { {GLOBAL} [x1 x2 y1 y2 x21 x22 y21 y22] FOREACH
266 x1 =  322 x2 =
130 y1 =  241 y2 =
140 x21 = 195 x22 =
133 y21 = 237 y22 =
30 ME SETALARM
}
ON ALARM { {GLOBAL} [x1 x2 y1 y2 x21 x22 y21 y22] FOREACH
ME GETSPOTSTATE lastStateME =
200 GETSPOTSTATE lastState2 =
0 lTempME =
MOUSEPOS tempY = tempX =
{{1 lTempME =} tempX x1 > tempX x2 < AND IF
{2 lTempME +} tempX x1 > tempX x2 < AND IF
} tempY y1 > tempY y2 < AND IF
{lTempME ME SETSPOTSTATELOCAL
{"@0,0 )POP To Slot Machines Hall" SAY } {0 0 MOVE} lTempME 0 <> IFELSE
} lTempME lastStateME <> IF
0 lTemp2 =
{{1 lTemp2 =} tempX x21 > tempX x22 < AND IF
{2 lTemp2 +} tempX x21 > tempX x22 < AND IF
} tempY y21 > tempY y22 < AND IF
{lTemp2 200 SETSPOTSTATELOCAL
{"@0,0 )POP To BlackJack Entrance" SAY} {0 0 MOVE} lTemp2 0 <> IFELSE
} lTemp2 lastState2 <> IF
30 ME SETALARM
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		LOCKABLE
		ID 86
		OUTLINE 479,5  505,5  505,30  479,30
		LOC 497,5
		SCRIPT
;~MediaList~;CasinoBack.wav		
ON ENTER {stop GLOBAL 0 stop = 10 ME SETALARM
"Say Stop to stop the environmental noise" LOCALMSG
"Script And Graphics by XTô ©2000" STATUSMSG
}
ON ALARM {stop GLOBAL {"CasinoBack.wav" SOUND 520 ME SETALARM} stop NOT IF}
ON OUTCHAT {stop GLOBAL CHATSTR LOWERCASE lowchat =
{1 stop = 86 UNLOCK} lowchat "ms" SUBSTR lowchat "stop" SUBSTR OR IF
}
ON LEAVE {86 UNLOCK}
		ENDSCRIPT
		ENDSPOT
	ENDROOM