ROOM
	ID 94
	NAME "Prop Generator"
	PICT "pal38.gif"
	PICTURE ID 1 NAME "arrowll.gif" TRANSCOLOR 56 ENDPICTURE
	PICTURE ID 2 NAME "arrowrr.gif" TRANSCOLOR 56 ENDPICTURE
	SPOT
		ID 1
		NAME "Next"
		DONTMOVEHERE
		OUTLINE 398,4  500,4  500,41  398,41
		LOC 479,13
		SCRIPT
ON SELECT {
cmd GLOBAL
"next" cmd =
1 4 SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "Reset"
		DONTMOVEHERE
		OUTLINE 406,57  508,57  508,96  406,96
		LOC 486,66
		SCRIPT
ON SELECT {
cmd GLOBAL
"reset" cmd =
1 4 SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		NAME "Previous"
		DONTMOVEHERE
		OUTLINE 7,6  168,6  168,42  7,42
		LOC 36,15
		SCRIPT
ON SELECT {
cmd GLOBAL
"prev" cmd =
1 4 SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		NAME "alarm"
		OUTLINE 235,4  250,4  250,15  235,15
		LOC 242,9
		SCRIPT
ON ALARM {
[
"958703651 958703668 958703674"
"958958815"
"958958805"
"958958773"
"958958837"
"957247021"
] thearray = thearray length noarray =
x1 GLOBAL
cmd GLOBAL
{
"There are " noarray ITOA + " avatars in this room." + statusmsg
{ "use 'rew' and 'forward' to select the ones you like" statusmsg } 60 ALARMEXEC
-1 x1 =
60 400 RANDOM + gotox =
60 200 RANDOM + gotoy =
{
i++
gotox POSX - 10 / POSX + newx =
gotoy POSY - 10 / POSY + newy =
newx newy SETPOS
} { i 30 < } WHILE
} cmd "init" == IF
{
x1 ++
{ 0 x1 = } 1 x1 + noarray > IF
"Now showing: avatar " 1 x1 + itoa + "/" + noarray itoa + logmsg
thearray x1 get xpropo =
"[" xpropo + "] SETPROPS" + xpropo =
xpropo STRTOATOM EXEC
} cmd "next" == IF
{
x1 --
{ noarray 1 - x1 = } x1 0 < IF
"Now showing: avatar " 1 x1 + itoa + "/" + noarray itoa + logmsg
thearray x1 get xpropo =
"[" xpropo + "] SETPROPS" + xpropo =
xpropo STRTOATOM EXEC
} cmd "prev" == IF
{
"Resetting Buttons to Start" logmsg
naked
-1 x1 =
} cmd "reset" == IF
}
;ON ENTER {
;x1 GLOBAL
;cmd GLOBAL
;"init" cmd =
;1 x1 =
;1 me SETALARM
}
ON SELECT {
"Original script by Sting." statusmsg
{"'next' and 'prev' scripting by andre@trimm.nl" statusmsg } 120 ALARMEXEC
{ "You can use this script as long as this message stays intact" statusmsg
} 240 ALARMEXEC
{ "by the way, it's no use clicking here !" statusmsg } 360 ALARMEXEC }
;get your avatar ids routine, by Foxy- say "avids <description"
;to get a line in your log to put in this script
ON OUTCHAT {
{ "" CHATSTR = "\x22 " 0 tbl =
{tbl USERPROP ITOA + " " + tbl ++
} {tbl NBRUSERPROPS == NOT} WHILE
" \x22;" + "$1" GREPSUB + LOGMSG
} CHATSTR "^avids(.*)" GREPSTR IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 7
		DONTMOVEHERE
		DEST 209
		OUTLINE 455,349  507,349  507,379  455,379
		LOC 481,364
		PICTS 2,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 8
		DONTMOVEHERE
		DEST 216
		OUTLINE 5,355  58,355  58,379  5,379
		LOC 31,366
		PICTS 1,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDDOOR
	ENDROOM