ROOM
	ID 218
	NAME "Prop Hang Script"
	PICT "blpal54.gif"
	PICTURE ID 1 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		OUTLINE 6,6  25,6  25,22  6,22
		LOC 134,102
		SCRIPT
ON ENTER {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
"You must specify the number of props in the avatar by row and column." LOGMSG
"For example; Hang 3 3 -would put out an avatar that has 9 props to it." LOGMSG
"3 across and 3 down." LOGMSG }
ON OUTCHAT  {
{
"$1" GREPSUB ATOI nx =
"$2" GREPSUB ATOI ny =
{
{
NBRUSERPROPS nx ny * - ITOA " props left" & LOCALMSG
} nx ny * NBRUSERPROPS == NOT IF
MOUSEPOS 22 + 3 ny - 22 * - y = 22 + 3 nx - 22 * - x =
0 j = {
0 i = {
x i 44 * - y j 44 * - DROPPROP i ++
} { i nx < } WHILE
j ++
} { j ny < } WHILE
} {
"You only have " NBRUSERPROPS ITOA & " props, not " &
nx ny * ITOA & LOCALMSG
} nx ny * NBRUSERPROPS <= IFELSE
"" CHATSTR =
} CHATSTR "^hang ([1-9]) ([1-9])" GREPSTR IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 2
		DONTMOVEHERE
		DEST 263
		OUTLINE 4,354  63,354  63,380  4,380
		LOC 34,368
		PICTS 1,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 111
		OUTLINE 447,352  508,352  508,378  447,378
		LOC 478,364
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
		ENDSCRIPT
		ENDDOOR
	ENDROOM