ROOM
	ID 216
	NAME "Offer/Accept Script"
	PICT "pal25.gif"
	PICTURE ID 1 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	DOOR
		ID 1
		NAME "Door 1"
		SHOWNAME
		OUTLINE 12,229  64,229  64,254  12,254
		LOC 38,236
		SCRIPT
ON ENTER {
offeredAvatar GLOBAL
offerInScript GLOBAL
offerOutScript GLOBAL
{
offeredAvatar GLOBAL prps GLOBAL
{
"$1" GREPSUB prps =
{
"[ " prps & " ] SETPROPS" & offeredAvatar =
"@" WHOCHAT WHOPOS ITOA SWAP ITOA "," & SWAP & &
" You have been offered an avatar by " & WHOCHAT WHONAME &
". To accept it, type \"accept\"." & LOCALMSG
} prps ".* .* .* .* .* .* .* .* .* .*" GREPSTR NOT
prps "-$" GREPSTR NOT AND prps "- " GREPSTR NOT AND
prps ">$" GREPSTR NOT AND prps "> " GREPSTR NOT AND
prps "<$" GREPSTR NOT AND prps "< " GREPSTR NOT AND
WHOCHAT WHOME <> AND IF
"" CHATSTR =
} CHATSTR "^;avoffer [\[] ([0-9<>A-Fa-f -]+) [\]]" GREPSTR IF
} offerInScript DEF
{
offeredAvatar GLOBAL
{
{
{
0 i = ";avoffer [ "
{
i USERPROP ITOA & " " & i ++
} { i NBRUSERPROPS < } WHILE "]" & WHOTARGET PRIVATEMSG
} NBRUSERPROPS IF
}
{
"You have to whisper the offer." STATUSMSG
} WHOTARGET IFELSE
"" CHATSTR =
} CHATSTR "offer" == IF
{
"" CHATSTR = offeredAvatar STRTOATOM EXEC
} "accept" CHATSTR == "\"accept\"" CHATSTR == OR offeredAvatar "" <> AND IF
{
"" CHATSTR =
} CHATSTR "^;avoffer" GREPSTR IF
} offerOutScript DEF
}
;this part goes in every room:
ON OUTCHAT { offerOutScript GLOBAL offerOutScript EXEC }
ON INCHAT { offerInScript GLOBAL offerInScript EXEC }
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 2
		NAME "Door 2"
		DONTMOVEHERE
		SHOWNAME
		OUTLINE 11,263  62,263  62,292  11,292
		LOC 37,272
		SCRIPT
;this part goes in every room:
ON OUTCHAT { offerOutScript GLOBAL offerOutScript EXEC }
ON INCHAT { offerInScript GLOBAL offerInScript EXEC }
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 94
		OUTLINE 453,4  507,4  507,22  453,22
		LOC 481,13
		PICTS 1,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER {
"Copy door 1 at your gate....copy door 2 to all of the rooms you want to be able to trade avs in :)" LOCALMSG
"@511,0 Now with two versions! Use door 1a at your gate, and 2a in all rooms you want it in for the second version!" LOCALMSG
"@511,0 :both versions are used in the exact same way, the second is simply Foxy's version- all differences are behind the scene" LOCALMSG
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 4
		DONTMOVEHERE
		DEST 217
		OUTLINE 6,7  64,7  64,28  6,28
		LOC 33,17
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON ENTER {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 5
		NAME "Door 1a"
		DONTMOVEHERE
		SHOWNAME
		SHOWFRAME
		OUTLINE 8,299  63,299  63,334  8,334
		LOC 35,310
		SCRIPT
ON SIGNON { offerin GLOBAL offerout GLOBAL
{ accav GLOBAL
  { "[ $1 ]" GREPSUB acv =
    { acv accav =
    } acv STRTOATOM EXEC LENGTH DUP 10 < AND IF
  } CHATSTR "^;offav ([ 0-9-]+)$" GREPSTR WHOCHAT WHOME != AND IF
} offerin GLOBAL
{ accav GLOBAL
 { 0 cr = ";offav " av =
  { av " " & cr USERPROP ITOA & av = cr ++ }
  { cr NBRUSERPROPS < } WHILE
  av CHATSTR = "I am offering you this av. Say accept to take it." WHOTARGET PRIVATEMSG
 } CHATSTR "offer" == WHOTARGET AND IF
 { { "" CHATSTR = accav " SETPROPS " & STRTOATOM EXEC } CHATSTR "accept" == IF
 } accav 0 == NOT IF
} offerout GLOBAL
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 6
		NAME "Door2a"
		DONTMOVEHERE
		SHOWNAME
		SHOWFRAME
		OUTLINE 8,341  60,341  60,376  8,376
		LOC 35,350
		SCRIPT
ON INCHAT { offerin GLOBAL offerin EXEC }
ON OUTCHAT { offerout GLOBAL offerout EXEC }
		ENDSCRIPT
		ENDDOOR
	ENDROOM