ROOM
	ID 198
	PRIVATE
	NAME "LaserTag 2"
	PICT "ltag2.gif"
	DOOR
		ID 1
		NAME "click me to go to lasertag 1"
		DONTMOVEHERE
		DEST 196
		OUTLINE 395,159  448,159  448,278  395,273
		LOC 421,217
		SCRIPT
ON OUTCHAT {
{
")no !TAG!" MOUSEPOS SAYAT
0 255 0 pencolor
4 pensize
whome whopos mousepos line
paintclear
"" CHATSTR =
} CHATSTR "tag" == IF
{ CLEARLOOSEPROPS PAINTCLEAR "" CHATSTR = } CHATSTR "clean" == IF
}
ON INCHAT {
{
{
{ "@" posx itoa & "," & posy itoa & "!" & WHOCHAT WHONAME & " got me!!" & ROOMMSG
";you got me" WHOCHAT PRIVATEMSG
191 GOTOROOM
} "$3" GREPSUB "TAG" SUBSTR IF
} "$1" GREPSUB ATOI POSX - dup 40 < SWAP -40 > AND
"$2" GREPSUB ATOI POSY - dup 40 < swap -40 > AND AND IF
} CHATSTR "@(.*),(.*) (.*)" GREPSTR WHOCHAT WHOME == NOT AND IF
{ laserscore global laserscore ++
"You got " whochat whoname & " and now have " & laserscore itoa & " point(s)!" & localmsg
"You got " whochat whoname & " and now have " & laserscore itoa & " point(s)!" & statusmsg
} CHATSTR ";you got me" == WHOCHAT WHOME == NOT AND IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 2
		DONTMOVEHERE
		DEST 197
		OUTLINE 64,161  117,161  117,272  64,277
		LOC 90,217
		ENDDOOR
	ENDROOM