ROOM
	ID 154
	NOPAINTING
	NOCYBORGS
	NAME "Propola 2"
	PICT "Empty-Prop-2.gif"
	ARTIST "Wolf Al/script Barn"
	PICTURE ID 1 NAME "zn0.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 2 NAME "zn1.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 3 NAME "zn2.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 4 NAME "zn3.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 5 NAME "zn4.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 6 NAME "zn5.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 7 NAME "zn6.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 8 NAME "zn7.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 9 NAME "zn8.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 10 NAME "zn9.gif" TRANSCOLOR 181 ENDPICTURE
	PICTURE ID 14 NAME "buttonbarcolor.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 15 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 16 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "Basic Scripts"
		OUTLINE 4,5  20,5  20,17  4,17
		LOC 128,96
		SCRIPT
; This script was written by Tandika Star.
; Email: Iptscrae@aol.com
; Palace: tomes.ksv.com:9998
ON ENTER {
; Set up a counter to track which AV we're on.
cntr GLOBAL 0 cntr =
; Reset spotstates.
0 1 SETSPOTSTATE 0 1 SETSPOTSTATELOCAL
0 2 SETSPOTSTATE 0 2 SETSPOTSTATELOCAL
0 3 SETSPOTSTATE 0 3 SETSPOTSTATELOCAL
0 4 SETSPOTSTATE 0 4 SETSPOTSTATELOCAL
; Set inital position of user.
260 254 SETPOS
; Tell user how to get instructions.
"@" POSX ITOA + "," + POSY ITOA + "Click on the ? for instructions." + LOCALMSG
}
ON LEAVE {
; Clean up room when last person leaves.
{ CLEARLOOSEPROPS PAINTCLEAR
} NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "Tens"
		OUTLINE 29,70  40,70  40,86  29,86
		LOC 35,78
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 8,0,0 9,0,0 10,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 3
		NAME "Ones"
		OUTLINE 45,69  58,69  58,85  45,85
		LOC 52,78
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 8,0,0 9,0,0 10,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 4
		NAME "Player Buttons"
		DONTMOVEHERE
		OUTLINE 260,345  505,346  505,370  260,371
		LOC 384,359
		PICTS 14,0,0 ENDPICTS
		SCRIPT
ON SELECT { cntr GLOBAL MOUSEPOS y = x =
; Determine which button has been pushed, by getting the position of the mouse.
; Set the spot's state locally to indicate which button was pushed.
; Use the alarm handler to actually perform the action associated with the spot.
; Button1: Go to the beginning.
{ 1 1 SETSPOTSTATELOCAL 30 ME SETALARM } 288 x > IF
; Button2: Go to the end.
{ 2 1 SETSPOTSTATELOCAL 30 ME SETALARM } 288 x < 318 x > AND IF
; Button3: Single-step forward.
{ 3 1 SETSPOTSTATELOCAL 30 ME SETALARM } 318 x < 348 x > AND IF
; Button4: Pause display.
{ 4 1 SETSPOTSTATELOCAL "@" POSX ITOA + "," + POSY ITOA + " !Paused!" + LOCALMSG } 379 x < 408 x > AND IF
; Button5: Stop display entirely. Resets display.
{ 0 1 SETSPOTSTATELOCAL "@" POSX ITOA + "," + POSY ITOA + "!Stopped!" + LOCALMSG
0 cntr = NAKED 0 2 SETSPOTSTATELOCAL 0 3 SETSPOTSTATELOCAL } 408 x < 438 x > AND IF
; Button6: Play continuously backwards.
{ 5 1 SETSPOTSTATELOCAL 30 ME SETALARM } 408 x < 438 x > AND IF
; Button7: Play continuously forwards.
{ 6 1 SETSPOTSTATELOCAL 30 ME SETALARM } 438 x < 468 x > AND IF
; Button8: Display help for player.
{ "@" POSX ITOA + "," + POSY ITOA + " The instructions are in your log." + LOCALMSG
"The buttons, from left to right, do the following:" LOGMSG
"1. Go to the first avatar" LOGMSG
"2. Go to the last avatar" LOGMSG
"3. Go to next avatar" LOGMSG
"4. Pause" LOGMSG
"5. Stop the player and reset" LOGMSG
"6. Play back through avatars." LOGMSG
"7. Play forward through avatars." LOGMSG
"8. Help (display this information)" LOGMSG
} 468 x < IF } ON ALARM { cntr GLOBAL
; Set up the array of Avatars. The first item in the array is always [0].
; Up to 31 Avatars can be in the array. Each Avatar can consist of up to 9 props.
[ [ 958703651 958703668 958703674 ]
[ 958958815 ]
[ 958958805 ]
[ 958958773 ]
[ 958958837 ]
[ 957247021 ]
] prps =
;Button1: Set to the beginning.
{ 1 cntr = prps cntr GET SETPROPS } 1 1 GETSPOTSTATE == IF
;Button2: Set to the end.
{ prps LENGTH 1 - cntr = prps cntr GET SETPROPS } 2 1 GETSPOTSTATE == IF
;Button3: Single step. Tells user if they try to go past the end.
{ cntr ++ { "@" POSX ITOA + "," + POSY ITOA + "!You're at the end" + LOCALMSG prps LENGTH 1 - cntr = } prps LENGTH cntr == IF
prps cntr GET SETPROPS } 3 1 GETSPOTSTATE == IF ; single step
;Button6: Display continuously backwards. Tells user if they try to go past beginning.
{  cntr -- { "@" POSX ITOA + "," + POSY ITOA + "!You're at the beginning" + LOCALMSG 1 cntr = } 0 cntr >= IF
prps cntr GET SETPROPS { 300 ME SETALARM } 1 cntr < IF } 5 1 GETSPOTSTATE == IF ; play back
;Button7: Displays continuously forwards. Tells user if they try to go past the end.
{  cntr ++ { "@" POSX ITOA + "," + POSY ITOA + "!You're at the end" + LOCALMSG prps LENGTH 1 - cntr = } prps LENGTH cntr == IF prps cntr GET SETPROPS { 300 ME SETALARM } prps LENGTH 1 - cntr > IF } 6 1 GETSPOTSTATE == IF ; play forward
;Increment or decrement counter as needed
{ cntr 10 / 2 SETSPOTSTATELOCAL cntr 10 % 3 SETSPOTSTATELOCAL }
{ cntr 3 SETSPOTSTATELOCAL 0 2 SETSPOTSTATELOCAL } 9 cntr < IFELSE
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 5
		DONTMOVEHERE
		DEST 173
		OUTLINE 61,99  117,99  117,119  61,119
		LOC 88,109
		PICTS 15,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 6
		DONTMOVEHERE
		DEST 114
		OUTLINE 384,97  439,97  439,118  384,118
		LOC 412,107
		PICTS 16,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM