ROOM
	ID 145
	PRIVATE
	NAME "Password Scripts"
	PICT "pal17.gif"
	PICTURE ID 1 NAME "himbun.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "blank.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 3 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "Password 1"
		SHOWNAME
		OUTLINE 213,9  287,9  287,37  213,37
		LOC 251,16
		SCRIPT
ON OUTCHAT {
;silence chatstr first so you dont say the password in the room you are going to
{ "" CHATSTR =
;roomnumbergoeshere
86 GOTOROOM
;password goes here
} CHATSTR "pass" == IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "Username Password Script"
		SHOWNAME
		OUTLINE 185,43  333,43  333,73  185,73
		LOC 258,50
		SCRIPT
ON OUTCHAT {
{ "" CHATSTR =
100 GOTOROOM
} CHATSTR "Pass" == "Name" USERNAME == AND IF }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		NAME "Frodo's Multi Password Script"
		SHOWNAME
		OUTLINE 176,79  339,79  339,106  176,106
		LOC 257,85
		SCRIPT
ON OUTCHAT {
{ "$1" GREPSUB pw =
{ dta =
{ dta 1 GET GOTOROOM
} pw dta 0 GET == IF
}
[ [ "pass1" 999 ] ;just add keywords and room ids as shown here
[ "pass2" 716 ]
[ "pass3" 724 ]
[ "pass4" 114 ] ] FOREACH
} CHATSTR "^(.*)$" GREPSTR IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		DONTMOVEHERE
		OUTLINE 100,99  140,99  140,151  100,151
		LOC 114,125
		PICTS 1,0,0 2,0,0 ENDPICTS
		SCRIPT
;use pics with your password script.
ON ENTER { 1 ME SETSPOTSTATELOCAL }
ON SELECT { 0 ME SETSPOTSTATELOCAL
"@100 171 You need to say a password to enter this room." LOCALMSG
}
ON OUTCHAT {
{ "" CHATSTR = 1 ME SETSPOTSTATELOCAL ME DEST GOTOROOM
} CHATSTR "password" == IF
}
ON LEAVE { 1 ME SETSPOTSTATELOCAL }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 5
		NAME "You can stay if your name is here..."
		SHOWNAME
		OUTLINE 164,115  348,115  348,139  164,139
		LOC 257,120
		SCRIPT
;will send people to another palace if their name isnt on this list.
ON SIGNON {
{ "palace://www.someotherpalace" NETGOTO }
"Tom" USERNAME == NOT
"Dick" USERNAME == NOT AND
"Harry" USERNAME == NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		NAME "Multiple Passwords for Different Rooms"
		SHOWNAME
		OUTLINE 151,183  354,183  354,205  151,205
		LOC 252,187
		SCRIPT
ON OUTCHAT {
{ "" CHATSTR = 150 GOTOROOM } CHATSTR "PASSWORD" == IF
{ "" CHATSTR = 151 GOTOROOM } CHATSTR "PASSWORD2" == IF
{ "" CHATSTR = 152 GOTOROOM } CHATSTR "PASSWORD"3 == IF
{ "" CHATSTR = 153 GOTOROOM } CHATSTR "PASSWORD4" == IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 7
		NAME "Password 2 With On Select Message"
		SHOWNAME
		OUTLINE 157,149  351,149  351,171  157,171
		LOC 253,154
		SCRIPT
ON SELECT { "You must say the password to enter this room." LOCALMSG }
ON OUTCHAT {
{ "" CHATSTR =
101 GOTOROOM
} "password" LOWERCASE CHATSTR == IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 8
		NAME "You Must Say the Password to Leave this Room"
		SHOWNAME
		OUTLINE 133,214  378,214  378,238  133,238
		LOC 255,219
		SCRIPT
; this code is placed in the gate room
ON SIGNON {
keyroom GLOBAL
goback GLOBAL
{    keyroom GLOBAL
{  103 GOTOROOM } keyroom 0 > IF
} goback DEF
}
; this code is placed in every room including the gate room
; but excepting the password room
ON ENTER { goback GLOBAL goback EXEC }
;this code is place on the password room
ON ENTER { keyroom GLOBAL 1 keyroom =
"Please say the password to leave this room" LOCALMSG
}
ON OUTCHAT { keyroom GLOBAL
{ 0 keyroom = "" CHATSTR = } "password" CHATSTR == IF
}
ON LEAVE { keyroom GLOBAL
{ "You didn't say the password" LOCALMSG
} keyroom  0 > IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 9
		DONTMOVEHERE
		DEST 153
		OUTLINE 4,361  58,361  58,381  4,381
		LOC 29,372
		PICTS 3,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 10
		DONTMOVEHERE
		DEST 103
		OUTLINE 452,360  509,360  509,380  452,380
		LOC 482,370
		PICTS 4,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM