ROOM
	ID 130
	NOCYBORGS
	NAME "Pictionary Room"
	PICT "pic_screen2.gif"
	ARTIST "Alan & Tish"
	PICTURE ID 1 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	DOOR
		ID 3
		DONTMOVEHERE
		OUTLINE 430,10  509,10  509,34  430,34
		LOC 469,22
		PICTS 26478,0,0 ENDPICTS
		SCRIPT
;Alan's Pictionary Script.
;Put this in a 'new drawing' spot.
;When a person selects this spot the next thing they say will be saved
;as the picture they're going to draw.
;The script will alert the room if anybody guesses the picture and keep
;each person's score.
ON ENTER
{
	object GLOBAL
	"null" object =
	pictionaryscore GLOBAL
	0 pictionaryscore =
	"Say RULES to list them in your log." STATUSMSG
}
ON INCHAT
{
	object GLOBAL
	pictionaryscore GLOBAL
	team GLOBAL
	team1 GLOBAL
	team2 GLOBAL
;
	{ ")applause" SAY
	"You got it " WHOCHAT WHONAME & " ... " & object & SAY
	"null" object =
	0 ME SETSPOTSTATE
	} CHATSTR object SUBSTR
	  WHOCHAT ME GETSPOTSTATE == NOT AND IF
;
	{
		{ pictionaryscore ++
			{ team1 GETSPOTSTATE 1 + team1 SETSPOTSTATE } team 1 == IF
			{ team2 GETSPOTSTATE 1 + team2 SETSPOTSTATE } team 2 == IF
		} "$1" GREPSUB USERNAME SUBSTR IF
	} CHATSTR "You got it (.*)" GREPSTR IF
;
	{ "I have solved " pictionaryscore ITOA & " pictures." & SAY
	"" CHATSTR =
	} CHATSTR ";scores" == IF
;
	{ "I solved " pictionaryscore ITOA & " pictures." & SAY
	0 pictionaryscore =
	PAINTCLEAR
	} CHATSTR ";resetscores" == IF
}
ON OUTCHAT
{
	object GLOBAL
;
	{ "Use your paint pallet to draw your picture." LOGMSG
	"You'll have to turn off painting to use the game buttons." LOGMSG
	"Team play is optional." LOGMSG
                "Type what you want the other side to guess." LOGMSG
                "The script will announce when the object is guessed." LOGMSG
	"Scripts are turned off in this room to protect the drawing." LOGMSG
	"" CHATSTR =
	} "rules" CHATSTR == IF
;
	{ CHATSTR object =
	"You have entered the following object ... " object & LOCALMSG
	"You can start guessing now." SAY
	"" CHATSTR =
	} object "null" ==
	  WHOME ME GETSPOTSTATE == AND IF
}
ON SELECT
{
	object GLOBAL
	"null" object =
	WHOME ME SETSPOTSTATE
	"I'm starting a new game." SAY
	PAINTCLEAR
	"Say the name of the object you're going to draw." LOCALMSG
	"If you make a mistake, select 'Start' again." LOCALMSG
}
ON LEAVE {
	{ CLEARLOOSEPROPS PAINTCLEAR
	0 ME SETSPOTSTATE
	} NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 4
		NAME "Reset Scores"
		DONTMOVEHERE
		OUTLINE 431,82  510,82  510,107  431,107
		LOC 470,94
		SCRIPT
;Place this script in a 'reset scores' spot.
ON SELECT
{
	team1 GLOBAL
	team2 GLOBAL
	team1 GETSPOTSTATE score1 =
	team2 GETSPOTSTATE score2 =
	"Team 1 got " score1 ITOA & " points.  Team 2 got " & score2 ITOA & " points." & ROOMMSG
	{ "Its a tie!" ROOMMSG }
	{
		{"Team 1 Wins!" ROOMMSG } { "Team 2 Wins!" ROOMMSG } score1 score2 > IFELSE
	} score1 score2 == IFELSE
	"Resetting scores." ROOMMSG
	0 team1 SETSPOTSTATE
	0 team2 SETSPOTSTATE
	";resetscores" SAY
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 7
		NAME "Join Team 1"
		DONTMOVEHERE
		OUTLINE 326,12  368,12  368,53  326,53
		LOC 357,23
		SCRIPT
ON ENTER
{
	team1 GLOBAL
	ME team1 =
}
ON SELECT
{
	team GLOBAL
	1 team =
	"I've joined Team 1." SAY
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 8
		NAME "Join Team 2"
		DONTMOVEHERE
		OUTLINE 325,66  367,66  367,108  325,108
		LOC 357,77
		SCRIPT
ON ENTER
{
	team2 GLOBAL
	ME team2 =
}
ON SELECT
{
	team GLOBAL
	2 team =
	"I've joined Team 2." SAY
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 6
		DONTMOVEHERE
		OUTLINE 434,46  506,46  506,74  434,74
		LOC 378,142
		SCRIPT
;Place this script in a 'scores' spot
ON SELECT
{
	team1 GLOBAL
	team2 GLOBAL
	"Team 1 has " team1 GETSPOTSTATE ITOA & " points.  Team 2 has " & team2 GETSPOTSTATE ITOA & " points." & ROOMMSG
	";scores" SAY
}
		ENDSCRIPT
		ENDDOOR
	DOOR
		ID 9
		DONTMOVEHERE
		DEST 999
		OUTLINE 4,354  62,354  62,380  4,380
		LOC 33,366
		PICTS 1,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 10
		DONTMOVEHERE
		DEST 121
		OUTLINE 448,354  508,354  508,379  448,379
		LOC 480,368
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM