ROOM
	ID 126
	NOCYBORGS
	NAME "Kahlua's Yahtzee"
	PICT "kyotsbroom.gif"
	ARTIST "Kahlua"
	PICTURE ID 1 NAME "onept.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "dicered1.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 3 NAME "dicered2.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "dicered3.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 5 NAME "dicered4.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 6 NAME "dicered5.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 7 NAME "dicered6.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 8 NAME "yahtholdt.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 9 NAME "1kmark.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 10 NAME "2kmark.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 11 NAME "3kmark.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 12 NAME "3xkmark.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 13 NAME "3lightk.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 14 NAME "dicer1.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 15 NAME "dicer2.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 16 NAME "dicer3.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 19 NAME "kyotsbscore.gif" TRANSCOLOR 127 ENDPICTURE
	PICTURE ID 17 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 18 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 28
		NAME "Game Button"
		DONTMOVEHERE
		OUTLINE 215,4  267,4  267,26  215,26
		LOC 241,15
		PICTS 1,0,0 19,15,50 ENDPICTS
		SCRIPT
ON ENTER {
{ 3 26 SetSpotState} 24 GetSpotState NOT IF
{ 0 28 SETSPOTSTATE } NBRROOMUSERS 1 <= IF
}
;
ON SELECT {
{ 0 ME SetSpotState } {1 ME SetSpotState} ME GetSpotState IFELSE
}
;
ON LEAVE { { PaintClear ClearLooseProps
0 i = { 0 i SetSpotState i ++ } { i 44 < } While
} NbrRoomUsers 2 < IF }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 1
		OUTLINE 147,37  176,37  176,64  147,64
		LOC 162,50
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 2
		OUTLINE 187,37  216,37  216,64  187,64
		LOC 202,50
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 3
		OUTLINE 227,37  256,37  256,64  227,64
		LOC 242,50
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 4
		OUTLINE 267,37  296,37  296,64  267,64
		LOC 282,50
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 5
		OUTLINE 307,37  336,37  336,64  307,64
		LOC 322,50
		PICTS 1,0,0 2,0,0 3,0,0 4,0,0 5,0,0 6,0,0 7,0,0 14,0,0 15,0,0 16,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 11
		DONTMOVEHERE
		OUTLINE 106,4  135,4  135,16  106,16
		LOC 140,10
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 0 GET crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,135 Ones - add " crv ITOA & " for subtotal of " & subtotal itoa & "." & LOCALMSG
"@512,135 You still need " need itoa & " for the 63 needed to get the 35 point bonus." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 12
		DONTMOVEHERE
		OUTLINE 106,18  135,18  135,30  106,30
		LOC 140,24
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 1 GET 2 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,135 Twos - add " crv ITOA & " for subtotal of " & subtotal itoa & "." & LOCALMSG
"@512,135 You still need " need itoa & " for the 63 needed to get the 35 point bonus." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 13
		DONTMOVEHERE
		OUTLINE 106,32  135,32  135,44  106,44
		LOC 140,38
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 2 GET 3 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,135 Threes - add " crv ITOA & " for subtotal of " & subtotal itoa & "." & LOCALMSG
"@512,135 You still need " need itoa & " for the 63 needed to get the 35 point bonus." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 14
		DONTMOVEHERE
		OUTLINE 106,46  135,46  135,58  106,58
		LOC 140,52
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 3 GET 4 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,135 Fours - add " crv ITOA & " for subtotal of " & subtotal itoa & "." & LOCALMSG
"@512,135 You still need " need itoa & " for the 63 needed to get the 35 point bonus." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 15
		DONTMOVEHERE
		OUTLINE 106,60  135,60  135,72  106,72
		LOC 140,66
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 4 GET 5 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,135 Fives - add " crv ITOA & " for subtotal of " & subtotal itoa & "." & LOCALMSG
"@512,135 You still need " need itoa & " for the 63 needed to get the 35 point bonus." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 16
		DONTMOVEHERE
		OUTLINE 106,74  135,74  135,86  106,86
		LOC 140,80
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL ut GLOBAL myturn GLOBAL
{ dd STRTOATOM EXEC 5 GET 6 * crv = ME co = ut crv + subtotal =
63 subtotal - need =
"@0,135 Sixes - add " crv ITOA & " for subtotal of " & subtotal itoa & "." & LOCALMSG
"@512,135 You still need " need itoa & " for the 63 needed to get the 35 point bonus." & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 17
		DONTMOVEHERE
		OUTLINE 473,4  505,4  505,17  473,17
		LOC 511,10
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC ddav = 0 crv =
{ tdv = { dt crv = } tdv 2 > IF
} ddav FOREACH
ME co =
"@512,135 3 OF A KIND - That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 18
		DONTMOVEHERE
		OUTLINE 473,19  505,19  505,32  473,32
		LOC 511,25
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd STRTOATOM EXEC ddav = 0 crv =
{ tdv = { dt crv = } tdv 3 > IF
} ddav FOREACH
ME co =
"@512,135 4 OF A KIND - That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 19
		DONTMOVEHERE
		OUTLINE 473,34  505,34  505,47  473,47
		LOC 511,40
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd "[145]" GREPSTR NOT 25 * crv =
ME co =
"@512,135 FULL HOUSE - That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 20
		DONTMOVEHERE
		OUTLINE 473,49  505,49  505,62  473,62
		LOC 511,55
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd " [12] [12] [12] [12] " GREPSTR 30 * crv =
ME co =
"@512,135 SMALL STRAIGHT - That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 21
		DONTMOVEHERE
		OUTLINE 473,64  505,64  505,77  473,77
		LOC 511,70
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dd " 1 1 1 1 1 " GREPSTR 40 * crv =
ME co =
"@512,135 LARGE STRAIGHT - That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 22
		DONTMOVEHERE
		OUTLINE 473,94  505,94  505,107  473,107
		LOC 511,100
		PICTS 1,0,0 9,-12,0 ENDPICTS
		SCRIPT
ON SELECT { dd GLOBAL crv GLOBAL co GLOBAL dt GLOBAL
myturn GLOBAL
{ dt crv = ME co =
"@512,135 CHANCE - That will give you a score of " crv ITOA & LOCALMSG
} myturn ME GETSPOTSTATE NOT AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 23
		DONTMOVEHERE
		OUTLINE 473,79  505,79  505,92  473,92
		LOC 491,85
		PICTS 1,0,0 9,0,0 10,0,0 11,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 12,0,0 ENDPICTS
		SCRIPT
ON SELECT { yhtz GLOBAL co GLOBAL dd GLOBAL myturn GLOBAL
crv GLOBAL mysc GLOBAL btt GLOBAL
{ dd "5" SUBSTR yts =
{
{ "Sorry, you zeroed out your yahtzee line earlier- you are ineligible for a bonus." LOGMSG
} yts yhtz 0 < AND IF
{ "@160,150 )sdclap !" USERNAME " collects a Yahtzee bonus!" & & ROOMMSG
"Joker rules-- you get to score it on a regular line as well!" LOCALMSG
100 mysc += ME GETSPOTSTATE 1 + ME SETSPOTSTATE
1 btt = yhtz ++
} yts yhtz 0 > AND btt NOT AND IF
}
{ ;yahtzee for the first time, -1 if yts is 0, 1 if yts is 1
yts 50 * crv = ME co =
"@512,135 YAHTZEE - This will score you a " crv ITOA & LOCALMSG
{ "@155,150 !WARNING: zeroing out this box makes you ineligible for yahtzee bonuses!" LOCALMSG
} crv NOT IF
} yhtz IFELSE
} myturn IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 10
		DONTMOVEHERE
		OUTLINE 305,35  338,35  338,66  305,66
		LOC 321,50
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 9
		DONTMOVEHERE
		OUTLINE 265,35  298,35  298,66  265,66
		LOC 281,50
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 8
		DONTMOVEHERE
		OUTLINE 225,35  258,35  258,66  225,66
		LOC 241,50
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 7
		DONTMOVEHERE
		OUTLINE 185,35  218,35  218,66  185,66
		LOC 201,50
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		DONTMOVEHERE
		OUTLINE 145,35  178,35  178,66  145,66
		LOC 161,50
		PICTS 1,0,0 8,0,0 ENDPICTS
		SCRIPT
ON SELECT { myturn GLOBAL
{ ME GETSPOTSTATE NOT ME SETSPOTSTATE
} myturn 26 GETSPOTSTATE AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 24
		NAME "Start Game"
		DONTMOVEHERE
		OUTLINE 144,4  194,4  194,26  143,26
		LOC 169,17
		SCRIPT
ON ENTER { { "A game of yahtzee is currently being played- click play to join!" LOCALMSG } ME GETSPOTSTATE WHONAME "." GREPSTR IF
{ 0 ME SETSPOTSTATE } ME GETSPOTSTATE WHOME == IF
{ POSX 160 RANDOM 224 + SETPOS } POSY 225 < IF
}
ON SELECT { ref GLOBAL plyrs GLOBAL ad GLOBAL hsc GLOBAL phsc GLOBAL
{ { "A game is currently in session. Click play to join." LOCALMSG }
{ "Resetting game, click again to start a new one." LOCALMSG
0 ME SETSPOTSTATE ";5" SAY
{ cr ++ 0 cr SETSPOTSTATE } { cr 23 < } WHILE
} ME GETSPOTSTATE WHONAME "." GREPSTR IFELSE
}
{ WHOME ME SETSPOTSTATE 1 ref = "" plyrs = "-" ad = 0 hsc = "" phsc =
"@155,20 !A game of Yahtzee has been started. Click \"Play\" to join!" ROOMMSG
} ME GETSPOTSTATE IFELSE
}
ON INCHAT { ref GLOBAL plyrs GLOBAL phsc GLOBAL hsc GLOBAL
{
{ DUP GLOBAL 0 SWAP =
} [ ref rollt crv mysc ut yhtz plyrs ckbxs myturn co phsc hsc btt ] FOREACH
"" plyrs =
} CHATSTR ";5" == IF
{ 0 ref = "" plyrs = "" phsc = 0 hsc =
} ref WHOME ME GETSPOTSTATE <> AND IF
}
ON OUTCHAT { { "" CHATSTR = } CHATSTR "^;" GREPSTR IF }
ON ALARM { plyrs GLOBAL hsc GLOBAL phsc GLOBAL ref GLOBAL
{ { "@512,35 !Game over!" ROOMMSG
{ "@165,135 !The winner is..." ROOMMSG
"@512,135 )sdclap !" phsc & "!!" & ROOMMSG
} hsc IF
0 ref = 1 sp =
{ 0 sp SETSPOTSTATE sp ++ } { sp 25 < } WHILE
{ ";5" SAY } 60 ALARMEXEC
} plyrs "." GREPSTR NOT IF
} ref IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 25
		NAME "PLAY"
		DONTMOVEHERE
		OUTLINE 278,75  339,75  339,107  278,107
		LOC 308,91
		SCRIPT
ON ENTER { ad GLOBAL "" ad =
"Foxy's script modified by Tex" LOGMSG
"Script enhancements by LoneWolfΏ and Kahlua" LOGMSG
"Graphics by Kahlua, inspired by new format by SpiritHawk" LOGMSG
}
ON OUTCHAT { ref GLOBAL plyrs GLOBAL
{ "" CHATSTR =
plyrs "^(.*)-[0-9+]-$" GREPSTR POP
"$1" GREPSUB plyrs = 1 25 SETALARM
} ref CHATSTR "remove player" == AND IF
}
ON SELECT { myturn GLOBAL btt GLOBAL
{ co GLOBAL crv GLOBAL mysc GLOBAL ut GLOBAL ckbxs GLOBAL
dd GLOBAL yhtz GLOBAL
{ crv mysc += "I have a score of " mysc ITOA & SAY
0 btt =
{ crv ut += } co 17 < IF
{ 1 co SETSPOTSTATE } co 23 < IF
{ 1 co SETSPOTSTATE dd "5" SUBSTR 2 * 1 - yhtz =
} co 23 == yhtz NOT AND IF
10 cs = 0 ckbxs = 1 vl =
{ cs ++ cs GETSPOTSTATE ckd = { 1 ckd = } cs co == IF
{ vl ckbxs += } ckd IF 2 vl *=
} { cs 22 < } WHILE
0 myturn =
"[ 0 0 0 0 0 0 ]" dd =
{ ";3" SAY }
{ { 35 mysc += "@0,40 !35 BONUS POINTS AWARDED!" LOCALMSG
} ut 62 > IF
";4" WHOME ITOA & "-" & mysc ITOA & SAY
{ DUP GLOBAL 0 SWAP =
} [ rollt crv mysc ut yhtz ckbxs myturn co btt ] FOREACH
} ckbxs 4095 < yhtz NOT OR IFELSE
} co IF
}
{ ";1" SAY "sdroll2" SOUND } myturn IFELSE
}
ON INCHAT { ref GLOBAL plyrs GLOBAL ad GLOBAL
mysc GLOBAL ckbxs GLOBAL ut GLOBAL yhtz GLOBAL
plyrs GLOBAL hsc GLOBAL phsc GLOBAL
ad "." GREPSTR stt =
{ "-" WHOCHAT ITOA & "-" & ad =
{ "You're already in the game, " WHOCHAT WHONAME &
WHOCHAT PRIVATEMSG
}
{ WHOCHAT WHONAME " has joined the game!" & Say
";2" WHOCHAT ITOA & WHOCHAT PRIVATEMSG
plyrs ad & plyrs =
} plyrs ad SUBSTR IFELSE
{ "" ad = } stt NOT IF
} CHATSTR ";1" == ref AND IF
{ ;initialize variables to play
0 mysc = 0 ckbxs = 0 ut = 0 yhtz =
} CHATSTR ";2" WHOME ITOA & == IF
{ 90 ME SETALARM
} ";3" CHATSTR == ref AND IF
{ "-$1-" GREPSUB pq =
"$2" GREPSUB ATOI ps =
"@0, 135 )sdclap !" "$1" GREPSUB ATOI WHONAME " has finished with a final score of " & &
"$2!" GREPSUB & ROOMMSG
{ "@150,35 !New high score for the game!" Say
"$1" GREPSUB ATOI WHONAME phsc = ps hsc =
} ps hsc > IF
plyrs "^(.*)" pq & "(.*)$" & GREPSTR POP
"$1$2" GREPSUB plyrs =
60 24 SETALARM 120 ME SETALARM
} CHATSTR "^;4([0-9]+)-([0-9]+)$" GREPSTR ref AND IF
{ { "$1$2" GREPSUB plyrs =
WHOCHAT WHONAME " has left the game." & Say
{ 1 ME SETALARM } "$2" GREPSUB "" == IF
} plyrs "^(.*)-" WHOCHAT ITOA "-(.*)$" & & GREPSTR IF
} CHATSTR ";6" == ref AND IF
}
ON ALARM { plyrs GLOBAL
plyrs "^-([0-9]+)-(.*)$" GREPSTR POP
"$1" GREPSUB cp = "$2" GREPSUB oth =
{ oth GREPSUB plyrs = plyrs "^-([0-9]+)-(.*)$" GREPSTR POP
"$1" GREPSUB cp = "$2" GREPSUB oth =
} { cp ATOI WHONAME "." GREPSTR NOT plyrs "" == NOT AND } WHILE
{ "@" cp ATOI WHOPOS ITOA SWAP ITOA "," & SWAP & & " " & cp ATOI WHONAME " is up!" & & ROOMMSG
";3" cp & cp ATOI PRIVATEMSG
oth "-" & cp & "-" & plyrs =
}
{ 30 24 SETALARM
} plyrs "" == NOT IFELSE
}
ON LEAVE { ";6" SAY }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 26
		NAME "Roll"
		DONTMOVEHERE
		OUTLINE 144,75  205,75  205,107  144,107
		LOC 173,91
		PICTS 13,-102,26 13,-150,26 13,-198,26 1,0,0 ENDPICTS
		SCRIPT
ON ENTER {
{ DUP GLOBAL 0 SWAP =
} [ ref rollt crv mysc ut yhtz plyrs ckbxs myturn co ] FOREACH
}
ON SELECT { ref GLOBAL ad GLOBAL rollt GLOBAL crv GLOBAL myturn GLOBAL
{ "" ad = 1 25 SETALARM }
{ { { ME GETSPOTSTATE 1 + ME SETSPOTSTATE
6 rollt = 0 crv =
1 ME SETALARM
}ME GETSPOTSTATE 3 < IF
} myturn IF
} ref ad ".." GREPSTR AND IFELSE
}
ON INCHAT {
mysc GLOBAL ckbxs GLOBAL ut GLOBAL yhtz GLOBAL
rollt GLOBAL myturn GLOBAL co GLOBAL
{ { 0 SWAP SETSPOTSTATE } [ 6 7 8 9 10 ] FOREACH
1 myturn = 11 sp = ckbxs tckbxs =
{ tckbxs DUP 2 / 2 * - sp SETSPOTSTATE
2 tckbxs /= sp ++
} { sp 23 < } WHILE
{ 1 23 SETSPOTSTATE
{ yhtz 23 SETSPOTSTATE } yhtz 1 > IF
}
{ 0 23 SETSPOTSTATE } yhtz IFELSE
0 ME SETSPOTSTATE 0 crv = 0 co =
{ 0 SWAP SETSPOTSTATE } [ 1 2 3 4 5 ] FOREACH
} ";3" WHOME ITOA & CHATSTR == IF
}
ON ALARM { rollt GLOBAL dd GLOBAL dt GLOBAL
crv GLOBAL 0 crv = co GLOBAL 0 co =
{ ")sdroll2" SAY } rollt 6 == IF
{ 0 cr = rollt --
{ cr ++
{ 7 rollt cr + DUP 3 / 3 * - + cr SETSPOTSTATE
} cr 5 + GETSPOTSTATE NOT IF
} { cr 5 < } WHILE
30 ME SETALARM
}
{ 1 27 SETALARM
} rollt IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 27
		NAME "Quit"
		DONTMOVEHERE
		OUTLINE 291,4  339,4  339,26  291,26
		LOC 314,15
		SCRIPT
ON SELECT { ref GLOBAL ";6" SAY
{ { DUP GLOBAL 0 SWAP =
} [ rollt crv mysc ut yhtz ckbxs myturn co btt ] FOREACH
}
{";5" WHOME PRIVATEMSG } ref IFELSE
}
ON ALARM { dt GLOBAL dd GLOBAL
0 dt = [ 0 0 0 0 0 0 ] dd =
{ dc = dc 5 + GETSPOTSTATE lck =
{ 6 RANDOM 1 + dv = dv dc SETSPOTSTATE }
{ dc GETSPOTSTATE dv = } lck NOT IFELSE
dv dt += dd dv 1 - GET 1 + dd dv 1 - PUT
} [ 1 2 3 4 5 ] FOREACH
"[ " { ITOA + " " + } dd FOREACH
" ]" & dd =
{ "@180,150 )sdclap !YAHTZEE!!" ROOMMSG
} dd "5" SUBSTR IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 28
		DONTMOVEHERE
		DEST 243
		OUTLINE 4,354  62,354  62,380  4,380
		LOC 33,366
		PICTS 17,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 29
		DONTMOVEHERE
		DEST 12322
		OUTLINE 448,354  508,354  508,379  448,379
		LOC 480,368
		PICTS 18,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM