ROOM
	ID 121
	NAME "Pong"
	PICT "pongroom.gif"
	ARTIST "Cid\B0"
	PICTURE ID 1 NAME "pongpad.gif" TRANSCOLOR 56 ENDPICTURE
	PICTURE ID 2 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 3 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "Start"
		DONTMOVEHERE
		OUTLINE 50,1  121,1  121,19  50,19
		LOC 178,97
		SCRIPT
ON SELECT {
obx GLOBAL
oby GLOBAL
xdir GLOBAL
ydir GLOBAL
dy GLOBAL
10 RANDOM dy =
cntr GLOBAL
bummer GLOBAL
0 cntr =
0 bummer =
0 xdir =
2 RANDOM ydir =
400 obx =
192 oby =
50 ME SETALARM
}
ON ALARM {
mspot GLOBAL
pong GLOBAL
tX GLOBAL
tY GLOBAL
obx GLOBAL
oby GLOBAL
xdir GLOBAL
ydir GLOBAL
dy GLOBAL
cntr GLOBAL
bummer GLOBAL
CLEARLOOSEPROPS
936630086 obx oby ADDLOOSEPROP
{ obx 40 + obx = }  { obx 40 - obx = } xdir 1 == IFELSE
{ oby 30 + dy + oby = }  { oby 30 - dy - oby = } ydir 1 ==IFELSE
{ xdir NOT xdir = 10 RANDOM dy =
MOUSEPOS pY = pX =
{ 1 pong = } obx 0 >= obx 48 <= AND oby   20 >= oby 105 <= AND AND IF
{ 2 pong = } obx 0 >= obx 48 <= AND oby 105 >= oby 188 <= AND AND IF
{ 3 pong = } obx 0 >= obx 48 <= AND oby 188 >= oby 271 <= AND AND IF
{ 4 pong = } obx 0 >= obx 48 <= AND oby 271 >= oby 354 <= AND AND IF
{ cntr ++ }
{
{  CLEARLOOSEPROPS "I hit it " cntr itoa + " times." + SAY
{ "New high score!" SAY cntr 6 SETSPOTSTATE } 6 GETSPOTSTATE cntr < IF
EXIT }
{ CLEARLOOSEPROPS "bummer..." SAY 1 bummer = EXIT }
cntr 0 == NOT IFELSE
}
mspot pong == IFELSE
} obx 26 <= IF
{ xdir NOT xdir =  } obx 446 > IF
{ ydir NOT ydir = } oby 20 < oby 328 > OR IF
{ 10 ME SETALARM }  bummer 0 == IF
}
ON LEAVE {
{ CLEARLOOSEPROPS  936630086 512 384  ADDLOOSEPROP }
NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "mspot 1"
		DONTMOVEHERE
		OUTLINE 9,13  45,13  45,114  9,115
		LOC 27,64
		PICTS 1,0,0 ENDPICTS
		SCRIPT
; Door 2 "mspot 1"
ON ENTER {
mspot GLOBAL
0 mspot =
1 ME SETSPOTSTATELOCAL
5 ME SETALARM
}
ON ALARM {
mspot GLOBAL
tX GLOBAL
tY GLOBAL
MOUSEPOS tY = tX =
{ mspot GLOBAL 0 ME SETSPOTSTATELOCAL 1 mspot = }
{ 1 ME SETSPOTSTATELOCAL }
tX 13 >= tX 48 <= AND tY 20 > tY 105 <= AND AND IFELSE
5 ME SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		NAME "mspot 2"
		DONTMOVEHERE
		OUTLINE 10,96  45,96  45,203  10,203
		LOC 27,149
		PICTS 1,0,0 ENDPICTS
		SCRIPT
ON ENTER {
1 ME SETSPOTSTATELOCAL
5 ME SETALARM
}
ON ALARM {
mspot GLOBAL
tX GLOBAL
tY GLOBAL
MOUSEPOS tY = tX =
{ mspot GLOBAL 0 ME SETSPOTSTATELOCAL 2 mspot = }
{ 1 ME SETSPOTSTATELOCAL   }
tX 13 >= tX 48 <= AND tY 105 > tY 188 <= AND AND IFELSE
5 ME SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		NAME "mspot 3"
		DONTMOVEHERE
		OUTLINE 10,187  46,188  46,284  10,284
		LOC 27,236
		PICTS 1,0,0 ENDPICTS
		SCRIPT
ON ENTER {
1 ME SETSPOTSTATELOCAL
5 ME SETALARM
}
ON ALARM {
mspot GLOBAL
tX GLOBAL
tY GLOBAL
MOUSEPOS tY = tX =
{ mspot GLOBAL 0 ME SETSPOTSTATELOCAL 3 mspot = }
{ 1 ME SETSPOTSTATELOCAL }
tX 13 >= tX 48 <= AND tY 188 > tY 271 <= AND AND IFELSE
5 ME SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 5
		NAME "mspot 4"
		DONTMOVEHERE
		OUTLINE 11,273  50,273  50,367  11,367
		LOC 30,320
		PICTS 1,0,0 ENDPICTS
		SCRIPT
ON ENTER {
1 ME SETSPOTSTATELOCAL
5 ME SETALARM
}
ON ALARM {
mspot GLOBAL
tX GLOBAL
tY GLOBAL
MOUSEPOS tY = tX =
{ mspot GLOBAL 0 ME SETSPOTSTATELOCAL 4 mspot = }
{ 1 ME SETSPOTSTATELOCAL  }
tX 13 >= tX 48 <= AND tY 271 > tY 354 <= AND AND IFELSE
5 ME SETALARM
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		NAME "Info"
		DONTMOVEHERE
		OUTLINE 378,2  439,2  439,20  378,20
		LOC 311,98
		SCRIPT
ON SELECT {
"Check you log for instructions..." LOCALMSG
"" LOGMSG
"Welcome to my single player version of PONG..." LOGMSG
"To play, select the start button..." LOGMSG
"Hold your mouse in the \"paddle\" area on the left of your screen..." LOGMSG
"and move it up and down to position the paddle so it strikes the ball..." LOGMSG
"That's it! I hope you enjoy this little game..." LOGMSG
"Email me with comments:  cidas@hotmail.com" LOGMSG
"Current High Score: " ME GETSPOTSTATE ITOA + LOGMSG
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 7
		DONTMOVEHERE
		DEST 328
		OUTLINE 7,6  63,6  63,28  7,28
		LOC 33,17
		PICTS 2,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 8
		DONTMOVEHERE
		DEST 293
		OUTLINE 450,4  505,4  505,24  450,24
		LOC 479,14
		PICTS 3,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM