ROOM
	ID 119
	NAME "Sweetypie Room"
	PICT "taterbed.gif"
	ARTIST "Art By Tater"
	PICTURE ID 4 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 5 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	DOOR
		ID 1
		OUTLINE 130,191  320,175  425,198  197,225
		LOC 268,197
		SCRIPT
ON SELECT { VTIME GLOBAL { 0 ME SETALARM } VTIME 1 < IF }
ON OUTCHAT { {
{ CHATSTR ", " +
[ "baby" "sugarlumps" "dollface" "honey" "honeyhead"
"pumpkin" "darling" "sugarlips" "sweetie" "sweetiepie"
"sweetums" "sugar" ]  12 RANDOM GET + "." +  CHATSTR =
} CHATSTR " " SUBSTR CHATSTR "^[:!@^)]" GREPSTR NOT AND IF } 6 INSPOT IF
}
ON ALARM
{
VTIME GLOBAL
VSTATE GLOBAL
{
{ 0 -2 MOVE } 6 INSPOT IF
5 6 SETALARM
1 VSTATE =
}
{
{ 0 2 MOVE } 6 INSPOT IF
VTIME 1 + VTIME =
{ 5 6 SETALARM }{ 0 VTIME = }
VTIME 20 < IFELSE
0 VSTATE =
} VSTATE 0 == IFELSE
}
		ENDSCRIPT
		ENDDOOR
	SPOT
		ID 2
		DONTMOVEHERE
		OUTLINE 472,160  511,160  512,241  472,240
		LOC 491,200
		SCRIPT
ON SELECT { ME GETSPOTSTATE lightstatus =
{ ":clap off" SAY 1 ME SETSPOTSTATE } 0 lightstatus == IF
{ ":clap on" SAY 0 ME SETSPOTSTATE } 1 lightstatus == IF
}
ON INCHAT {
{ 1 ME SETSPOTSTATE 90 DIMROOM 80 DIMROOM 70 DIMROOM 60 DIMROOM 50 DIMROOM } CHATSTR ":clap off" == IF
{ 0 ME SETSPOTSTATE 60 DIMROOM 70 DIMROOM 80 DIMROOM 90 DIMROOM 100 DIMROOM } CHATSTR ":clap on" == IF
}
ON ENTER {
{ 50 DIMROOM } 1 ME GETSPOTSTATE == IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 708
		OUTLINE 2,5  58,5  58,27  2,27
		LOC 30,18
		PICTS 4,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 4
		DONTMOVEHERE
		DEST 300
		OUTLINE 455,4  509,4  509,24  455,24
		LOC 483,14
		PICTS 5,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM