ROOM
	ID 118
	DROPZONE
	NAME "Apartment Script"
	PICT "clubhouse.gif"
	PICTURE ID 1 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 2 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		OUTLINE 485,5  505,5  505,24  485,24
		LOC 377,101
		SCRIPT
;Apartment Script by Glide
;The script is set up so the first person in the room is the room owner.
;To assign this room permanently to someone by name...
;remove the 2nd line in the ON ENTER section which looks like this:
;rowner GLOBAL 0 ROOMUSER WHONAME rowner =
;and in its place, put this line:
;rowner GLOBAL "RoomOwnerName" rowner =
;Don't use the semi-colon (;) at the beginning of the line...
;and put the room owner's name where it says RoomOwnerName
;
;Near the bottom of the script, in the ON ALARM section...
;change the room number to the room number that people are kicked to.
;
;This script can be sensitive to low flood limits.
;
ON ENTER {
rowner GLOBAL 0 ROOMUSER WHONAME rowner =
rkick GLOBAL 0 rkick =
{ "Welcome to your room, " USERNAME & ". Look in your log window for a list of commands." & LOCALMSG
roomcomm GLOBAL {
{ LOGMSG }
 [
  ""
  "ROOM COMMANDS:"
  ""
  ";kick"
  ";gag"
  ";ungag"
  ";propgag"
  ";unpropgag"
  ";pin"
  ";unpin"
  ";freeze"
  ";unfreeze"
  ";avlock"
  ";avunlock"
  ""
  "You must whisper the commands."
  "Type \"help\" to see this list again."
  ""
 ] FOREACH
} roomcomm DEF
roomcomm EXEC
} USERNAME rowner == IF
}
ON INCHAT {
rowner GLOBAL rpin GLOBAL rgag GLOBAL rkick GLOBAL
rpgag GLOBAL freeze GLOBAL frz GLOBAL avlock GLOBAL
avlck GLOBAL fx GLOBAL fy GLOBAL
{
{ 1 rgag = } CHATSTR ";gag" == WHOCHAT WHONAME rowner == AND IF
{ 0 rgag = } CHATSTR ";ungag" == WHOCHAT WHONAME rowner == AND IF
{ 1 rkick = 1 ME SETALARM
} CHATSTR ";kick" == WHOCHAT WHONAME rowner == AND IF
{ 1 rpgag = 0 avlock = 1 ME SETALARM
} CHATSTR ";propgag" == WHOCHAT WHONAME rowner == AND IF
{ 0 rpgag = } CHATSTR ";unpropgag" == WHOCHAT WHONAME rowner == AND IF
{ 1 rpin = 0 avlock = 0 freeze = 1 ME SETALARM
} CHATSTR ";pin" == WHOCHAT WHONAME rowner == AND IF
{ 0 rpin = NAKED } CHATSTR ";unpin" == WHOCHAT WHONAME rowner == AND IF
{ 1 freeze = POSX fx = POSY fy =
   POSX ITOA " " & POSY ITOA & " SETPOS" & frz = 1 ME SETALARM
} CHATSTR ";freeze" == WHOCHAT WHONAME rowner == AND IF
{ 0 freeze = } CHATSTR ";unfreeze" == WHOCHAT WHONAME rowner == AND IF
{ 1 avlock = 0 i = "[" { " " i USERPROP ITOA & & i ++ }
  { i NBRUSERPROPS < } WHILE " ] SETPROPS" & avlck = 1 ME SETALARM
}  CHATSTR ";avlock" == WHOCHAT WHONAME rowner == AND IF
{ 0 avlock = } CHATSTR ";avunlock" == WHOCHAT WHONAME rowner == AND IF
} USERNAME rowner == NOT IF
}
ON OUTCHAT {
rgag GLOBAL rowner GLOBAL
{ { "" CHATSTR = } rgag IF } USERNAME rowner == NOT IF
{ comm =
{ "" CHATSTR = "You must whisper the commands." LOCALMSG
} comm CHATSTR == WHOTARGET NOT AND USERNAME rowner == AND IF
} [ ";kick" ";gag" ";ungag" ";propgag" ";unpropgag" ";unpin"
    ";pin" ";freeze" ";unfreeze" ";avlock" ";avunlock" ] FOREACH
{ roomcomm GLOBAL roomcomm EXEC "" CHATSTR =
} CHATSTR "help" == USERNAME rowner == AND IF
}
ON ALARM {
rowner GLOBAL rpin GLOBAL rpgag GLOBAL rkick GLOBAL
freeze GLOBAL frz GLOBAL avlock GLOBAL avlck GLOBAL
fx GLOBAL fy GLOBAL
2 ME SETALARM
{
{ { [ 1280 ] SETPROPS 490 362 SETPOS
  } POSX 490 == POSY 362 == AND NOT IF
{ [ 1280 ] SETPROPS } 1280 TOPPROP == NOT IF } rpin IF
{ NAKED } rpgag NBRUSERPROPS AND IF
{ { frz STRTOATOM EXEC } POSX fx == POSY fy == AND NOT IF } freeze IF
{ { avlck STRTOATOM EXEC } 0 i = "["
  { " " i USERPROP ITOA & & i ++ } { i NBRUSERPROPS < } WHILE
  " ] SETPROPS" & dif = dif avlck == NOT IF } avlock IF
;change room number below to the room people are kicked to
{ 86 GOTOROOM } rkick IF
} USERNAME rowner == NOT IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 2
		DONTMOVEHERE
		DEST 232
		OUTLINE 7,352  66,352  66,379  7,379
		LOC 35,363
		PICTS 1,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 3
		DONTMOVEHERE
		DEST 135
		OUTLINE 446,355  505,355  505,380  446,380
		LOC 477,367
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER {
{ CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF
}
		ENDSCRIPT
		ENDDOOR
	ENDROOM