ROOM
	ID 1093
	NOCYBORGS
	NAME "Lines n' Boxes"
	PICT "dots3.gif"
	PICTURE ID 1 NAME "greepaw.gif" TRANSCOLOR 230 ENDPICTURE
	PICTURE ID 2 NAME "purpbutton.gif" TRANSCOLOR 230 ENDPICTURE
	PICTURE ID 3 NAME "arrowll.gif" TRANSCOLOR 0 ENDPICTURE
	PICTURE ID 4 NAME "arrowrr.gif" TRANSCOLOR 0 ENDPICTURE
	SPOT
		ID 1
		NAME "Green"
		DONTMOVEHERE
		OUTLINE 68,36  107,35  108,73  68,73
		LOC 87,54
		PICTS 1,0,0 ENDPICTS
		SCRIPT
ON SELECT {
{ WHOME ME SETSPOTSTATE
USERNAME " will play as Green." + ROOMMSG
{ ";ƒ00" SAY } 2 GETSPOTSTATE IF
}
{ ME GETSPOTSTATE WHONAME " is playing Green now." + LOCALMSG
} ME GETSPOTSTATE NOT IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		DONTMOVEHERE
		OUTLINE 410,33  449,34  450,75  410,75
		LOC 429,56
		PICTS 2,0,0 ENDPICTS
		SCRIPT
ON SELECT {
{ WHOME ME SETSPOTSTATE
USERNAME " will play as Purple." + ROOMMSG
{ ";ƒ00" SAY } 1 GETSPOTSTATE IF
}
{ ME GETSPOTSTATE WHONAME " is playing Purple now." + LOCALMSG
} ME GETSPOTSTATE NOT IFELSE
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		OUTLINE 354,355  356,355  356,357  354,357
		LOC 355,356
		PICTS 1,0,0 2,0,0 ENDPICTS
		ENDSPOT
	SPOT
		ID 3
		DONTMOVEHERE
		OUTLINE 160,90  362,90  362,292  160,292
		LOC 256,192
		SCRIPT
ON ENTER { lndhrt  GlOBAL hrtst GLOBAL
{ 1094 GOTOROOM } hrtst NOT IF
"fh_write" SOUND
"Script by Foxy, Graphics by Kittypaws, ©1999" STATUSMSG
}
ON OUTCHAT { xs GLOBAL ys GLOBAL pp GLOBAL gp GLOBAL lbt GLOBAL lndhrt GLOBAL
{ "[ 0 0 0 0 0 0 0 0 0 ]" xs = xs ys = "" pp = "" gp = 0 lbt =
PAINTCLEAR CLEARLOOSEPROPS 0 1 SETSPOTSTATE 0 2 SETSPOTSTATE 2 4 SETSPOTSTATE
} CHATSTR "reset" == ISWIZARD 1 GETSPOTSTATE WHOME == OR AND IF
1 lndhrt EXEC
}
ON SELECT { MOUSEPOS y = x =
{ y 77 - 25 / br = x 147 - 25 / bc =
{  ";ƒc"  bc ITOA +  y 90 - 25 / ITOA + SAY }
{  ";ƒr" br ITOA + x 160 - 25 / ITOA + SAY
} br 25 * 90 + y - DUP * bc 25 * 160 + x - DUP * > IFELSE
} WHOME 1 GETSPOTSTATE == WHOME 2 GETSPOTSTATE == OR IF
}
ON INCHAT { xs GLOBAL ys GLOBAL pp GLOBAL gp GLOBAL lbt GLOBAL lndhrt GlOBAL
{ [ 941583667 941583591 ] lbt 1 - GET 160 pc 25 * + 93 pr 25 * + ADDLOOSEPROP
[ { gp } { pp } ] lbt 1 - GET EXEC tb =
{ tb pc ITOA + pr ITOA + tb = }
{ pc ITOA pr ITOA + tb =
} tb "." GREPSTR IFELSE
tb [ { gp = } { pp = } ] lbt 1 - GET EXEC 2 act =
} putpiece DEF
{ "[ 0 0 0 0 0 0 0 0 0 ]" xs = xs ys = "" pp = "" gp =
PAINTCLEAR CLEARLOOSEPROPS 2 RANDOM 1 + lbt = lbt 1 - 4 SETSPOTSTATE
} CHATSTR ";ƒ00" == 1 GETSPOTSTATE WHOME == AND IF
{ "." ln = 0 gr = 0 pr =
{ { gr ++ } gp ln GREPSTR IF
{ pr ++ } pp ln GREPSTR IF
".." ln + ln =
} { pp ln GREPSTR gp ln GREPSTR OR } WHILE
"@40,40 Current score is" ROOMMSG
"@200,40 Green: " gr ITOA + ROOMMSG
"@350,40 Purple: " pr ITOA + ROOMMSG
}  CHATSTR ";ƒ01" == 1 GETSPOTSTATE WHOME == AND IF
2 lndhrt EXEC
}
ON LEAVE { lndhrt GLOBAL hrtst GLOBAL 0 hrtst = { } lndhrt DEF }
ON ALARM { lndhrt GLOBAL 3 lndhrt EXEC }
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 5
		NAME "Current Score"
		DONTMOVEHERE
		OUTLINE 12,338  148,338  148,367  12,367
		LOC 89,348
		SCRIPT
ON SELECT {
{ ";ƒ01" SAY
} 1 GETSPOTSTATE WHOME ==
2 GETSPOTSTATE WHOME == OR IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 7
		NAME "Rules"
		DONTMOVEHERE
		OUTLINE 386,336  450,336  450,367  387,367
		LOC 412,348
		SCRIPT
ON SELECT { "Instructions on how to play are in your log." LOCALMSG
"To start, each player clicks on the purple or green buttons at the top of the screen." LOGMSG
"Who goes first is random." LOGMSG
"The current player button shows whose turn it is." LOGMSG
"Players take turns clicking on the grid to draw lines." LOGMSG
"If a player completes a square when they click, they get a point and another turn." LOGMSG
"If the board is messed up, the green player can say redraw to redraw it-- USE SPARINGLY!" LOGMSG
"Either the green player or a wizard can say reset to clear the board for a new game." LOGMSG
"Either player can get the current score by clicking on the current score button." LOGMSG
"Player with most boxes at the end of the game wins." LOGMSG
{ "In wizard mode, say the word refresh to put on the props." LOGMSG } ISWIZARD IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 8
		DONTMOVEHERE
		DEST 191
		OUTLINE 4,354  62,354  62,380  4,380
		LOC 33,366
		PICTS 3,0,0 ENDPICTS
		ENDDOOR
	DOOR
		ID 9
		DONTMOVEHERE
		DEST 12441
		OUTLINE 448,354  508,354  508,379  448,379
		LOC 480,368
		PICTS 4,0,0 ENDPICTS
		SCRIPT
ON INCHAT { nDoIt GLOBAL nDoIt EXEC }
ON ENTER { { CLEARLOOSEPROPS PAINTCLEAR } NBRROOMUSERS 2 < IF }
		ENDSCRIPT
		ENDDOOR
	ENDROOM