ROOM
	ID 1000
	PRIVATE
	NOPAINTING
	NOCYBORGS
	NAME "Paintball  Armory"
	PICT "pbarmory2.gif"
	SPOT
		ID 1
		NAME "red team"
		DONTMOVEHERE
		OUTLINE 100,110  146,110  146,151  100,151
		LOC 123,135
		SCRIPT
ON SELECT {
{ GLOBAL } [ team bls ] FOREACH
{ 100 bls = 1 team = [ 1056608525 ] SETPROPS
} team NOT IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 2
		NAME "blue team"
		DONTMOVEHERE
		OUTLINE 177,110  221,110  221,149  177,149
		LOC 199,133
		SCRIPT
ON SELECT {
{ GLOBAL } [ team bls ] FOREACH
{ 100 bls = 2 team = [  -1284536128 ] SETPROPS
} team NOT IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 4
		NAME "Machine Gun - 100 Points"
		DONTMOVEHERE
		OUTLINE 258,172  388,172  388,187  258,187
		LOC 323,172
		SCRIPT
ON SELECT {
{ GLOBAL } [ team bls ngt ] FOREACH
{ 1 ngt = 100 bls -= "You now have " bls ITOA & " points." & STATUSMSG
} team ngt NOT AND bls 99 > AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 5
		NAME "Shotgun-- 50 Points"
		DONTMOVEHERE
		OUTLINE 260,153  365,153  365,168  260,168
		LOC 310,153
		SCRIPT
ON SELECT {
{ GLOBAL } [ team tst bls ] FOREACH
{ 50 bls -= 1 tst = "You have " bls ITOA & " points." & STATUSMSG
} team tst NOT AND bls 49 > AND IF
}
		ENDSCRIPT
		ENDSPOT
	DOOR
		ID 7
		NAME "Enter Arena"
		DEST 109
		OUTLINE 4,140  62,145  62,314  4,377
		LOC 41,286
		SCRIPT
ON SELECT {
base GLOBAL
base 1 + ent1 = base 2 + ent2 = base 3 + ent3 = base 4 + ent4 =
[ ent1 ent2 ent3 ent4 ] 4 RANDOM GET GOTOROOM
}
		ENDSCRIPT
		ENDDOOR
	SPOT
		ID 9
		NAME "3-pack of Shields-- 18 points"
		DONTMOVEHERE
		OUTLINE 260,130  404,129  404,145  259,145
		LOC 332,130
		SCRIPT
ON SELECT {
{ GLOBAL } [ team mxi bls ] FOREACH
{ 18 bls -= 3 mxi += "You have " bls ITOA & " points." & STATUSMSG
} team mxi NOT AND bls 17 > AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 6
		NAME "5-pack of Ammo-- 15 points"
		DONTMOVEHERE
		OUTLINE 259,111  397,111  397,126  261,126
		LOC 329,113
		SCRIPT
ON SELECT {
{ GLOBAL } [ team sts bls ] FOREACH
{ 15 bls -= 50 sts += "You have " bls ITOA & " points." & STATUSMSG
} team bls 14 > AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 8
		NAME "Nuclear Launcher-- 250 points"
		DONTMOVEHERE
		OUTLINE 258,194  411,194  411,208  258,208
		LOC 335,195
		SCRIPT
ON SELECT {
{ GLOBAL } [ team bls ken ] FOREACH
{ 1 ken = 250 bls -= "You now have " bls ITOA & " points." & STATUSMSG
} team ken NOT AND bls 249 > AND IF
}
		ENDSCRIPT
		ENDSPOT
	SPOT
		ID 3
		NAME "change team"
		DONTMOVEHERE
		OUTLINE 119,183  203,183  203,205  119,205
		LOC 338,198
		SCRIPT
ON SELECT {
{ GLOBAL } [ bls ngt tst sts fon team ken mxi ] FOREACH
[ bls ngt tst sts fon team ken mxi ocs fst ] glbls =
{ 0 glbls loop GET = loop ++ } { loop 8 < } WHILE
}
ON ENTER {
{ GLOBAL } [ ocs fst base team ] FOREACH
ROOMID base =
{ "Welcome to paintball! Say help to get instructions in your log." LOCALMSG
"@512,20 You can return to this room for supplies at any time by saying re-arm." LOCALMSG } team NOT IF
{ { "Say Inventory to get a list of weapons, ammo and point count in your log." LOGMSG
"Say fire to shoot your gun" LOGMSG
"Say hose to shoot a machine gun." LOGMSG
"Say shoot to shoot a shotgun." LOGMSG
"Say nuke to launch a nuclear weapon" LOGMSG
"Say re-arm to return to the starting room to buy more stuff." LOGMSG
"Whisper 'give -number- ammo' to give ammo to someone." LOGMSG
"YOu can also give shields and points in the same way." LOGMSG
} CHATSTR "help" == IF
{ base GLOBAL base GOTOROOM "" CHATSTR = } CHATSTR "re-arm" == IF
{ "You have " bls ITOA + " points." + LOGMSG
"You have " sts ITOA + " rounds of ammo." + LOGMSG
"You have " mxi ITOA + " shields." + LOGMSG
{ "You have a machine gun" LOGMSG } ntg IF
{ "You have a shotgun" LOGMSG } tst IF
{ "You have a nuclear launcher" LOGMSG } ken IF
"" CHATSTR =
} CHATSTR "inventory" == IF
}  ocs DEF
{
[ "!SPLAT!" "!SPLOT!" ] 2 team - GET fs =
[  923100285  -1284536128  ] team 1 - GET pp =
{ sts -- ")pop " fs + MOUSEPOS SAYAT
pp MOUSEPOS 22 - SWAP 22 - SWAP ADDLOOSEPROP
0 fon = 120 ME SETALARM
"" CHATSTR =
} sts CHATSTR "fire" == AND IF
{ sts -- ")pop " fs + MOUSEPOS SAYAT
pp MOUSEPOS 22 - SWAP 22 - SWAP ADDLOOSEPROP
"" CHATSTR =
} sts CHATSTR "hose" == AND IF
{ 3 sts -= MOUSEPOS y = x =
{ df = ")pop " fs + x df 0 GET + y df 1 GET + SAYAT
pp  x df 0 GET + 22 - y df 1 GET + 22 - ADDLOOSEPROP
} [ [ -22 -22 ] [ 22 0 ] [ -22 22 ] ] FOREACH
0 fon = 120 ME SETALARM
"" CHATSTR =
} sts 2 > CHATSTR "shoot" == AND tst AND IF
{ 19 sts -= MOUSEPOS y = x =
{ df = ")pop " fs + x df 0 GET + y df 1 GET + SAYAT
pp  x df 0 GET + 22 - y df 1 GET + 22 - ADDLOOSEPROP
} [ [ -22 -44 ] [ 0 -44 ] [ 22 -44 ] [ -33 -22 ] [ -11 -22 ]
[ 11 -22 ] [ 33 -22 ] [ -44 0 ] [ -22 0 ] [ 0 0 ]
[ -22 44 ] [ 0 44 ] [ 22 44 ] [ -33 22 ] [ -11 22 ]
[ 11 22 ] [ 33 22 ] [ 44 0 ] [ 22 0 ] ] FOREACH
0 fon = 120 ME SETALARM
"" CHATSTR =
}  sts 5 > CHATSTR "nuke" == AND ken AND IF
} fst DEF
}
ON OUTCHAT { ocs GLOBAL bls GLOBAL ngt GLOBAL tst GLOBAL sts GLOBAL
mxi GLOBAL ken GLOBAL
{ "Check your log for the instructions." LOCALMSG
"Click on red or blue first to get your paint." LOGMSG
"You start with 100 points, click on the ammo and weapons (prices marked) to get them." LOGMSG
"Weapons are: gun ( you start with this ), " LOGMSG
"machine gun ( no delay in shooting bullets ), " LOGMSG
"shotgun (3 shots in your general target area ), " LOGMSG
"nuclear launcher (19 shots in your target area)" LOGMSG
"shields (one shield lost for every shot that hits you)" LOGMSG
"and don't forget lots of ammo!" LOGMSG
"If you get killed in the arena, you come back here." LOGMSG
"You keep your weapons and ammo, but you must rejoin a team." LOGMSG
"Once you enter the arena, saying help will get you the playing options below:" LOGMSG
"" LOGMSG
} CHATSTR "help" == IF
ocs EXEC
}
		ENDSCRIPT
		ENDSPOT
	ENDROOM